3 files changed, 77 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/interpreters/tcl/8.5.nix b/nixpkgs/pkgs/development/interpreters/tcl/8.5.nix
new file mode 100644
index 000000000000..193ff4f93769
--- /dev/null
+++ b/nixpkgs/pkgs/development/interpreters/tcl/8.5.nix
@@ -0,0 +1,11 @@
+{ callPackage, fetchurl, ... } @ args:
+
+callPackage ./generic.nix (args // rec {
+  release = "8.5";
+  version = "${release}.18";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/tcl/tcl${version}-src.tar.gz";
+    sha256 = "1jfkqp2fr0xh6xvaqx134hkfa5kh7agaqbxm6lhjbpvvc1xfaaq3";
+  };
+})
diff --git a/nixpkgs/pkgs/development/interpreters/tcl/8.6.nix b/nixpkgs/pkgs/development/interpreters/tcl/8.6.nix
new file mode 100644
index 000000000000..d76ceb3421de
--- /dev/null
+++ b/nixpkgs/pkgs/development/interpreters/tcl/8.6.nix
@@ -0,0 +1,11 @@
+{ callPackage, fetchurl, ... } @ args:
+
+callPackage ./generic.nix (args // rec {
+  release = "8.6";
+  version = "${release}.9";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/tcl/tcl${version}-src.tar.gz";
+    sha256 = "0kjzj7mkzfnb7ksxanbibibfpciyvsh5ffdlhs0bmfc75kgd435d";
+  };
+})
diff --git a/nixpkgs/pkgs/development/interpreters/tcl/generic.nix b/nixpkgs/pkgs/development/interpreters/tcl/generic.nix
new file mode 100644
index 000000000000..e665e8cfb1ea
--- /dev/null
+++ b/nixpkgs/pkgs/development/interpreters/tcl/generic.nix
@@ -0,0 +1,55 @@
+{ lib, stdenv
+
+# Version specific stuff
+, release, version, src
+, ...
+}:
+
+stdenv.mkDerivation {
+  pname = "tcl";
+  inherit version;
+
+  inherit src;
+
+  outputs = [ "out" "man" ];
+
+  setOutputFlags = false;
+
+  preConfigure = ''
+    cd unix
+  '';
+
+  configureFlags = [
+    "--enable-threads"
+    # Note: using $out instead of $man to prevent a runtime dependency on $man.
+    "--mandir=${placeholder "out"}/share/man"
+    "--enable-man-symlinks"
+    # Don't install tzdata because NixOS already has a more up-to-date copy.
+    "--with-tzdata=no"
+    "tcl_cv_strtod_unbroken=ok"
+  ] ++ lib.optional stdenv.is64bit "--enable-64bit";
+
+  enableParallelBuilding = true;
+
+  postInstall = let
+    dllExtension = stdenv.hostPlatform.extensions.sharedLibrary;
+  in ''
+    make install-private-headers
+    ln -s $out/bin/tclsh${release} $out/bin/tclsh
+    ln -s $out/lib/libtcl${release}${dllExtension} $out/lib/libtcl${dllExtension}
+  '';
+
+  meta = with lib; {
+    description = "The Tcl scripting language";
+    homepage = "https://www.tcl.tk/";
+    license = licenses.tcltk;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ vrthra ];
+  };
+
+  passthru = rec {
+    inherit release version;
+    libPrefix = "tcl${release}";
+    libdir = "lib/${libPrefix}";
+  };
+}