1 files changed, 47 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/interpreters/luau/default.nix b/nixpkgs/pkgs/development/interpreters/luau/default.nix
new file mode 100644
index 000000000000..2341f8a5c70e
--- /dev/null
+++ b/nixpkgs/pkgs/development/interpreters/luau/default.nix
@@ -0,0 +1,47 @@
+{ lib, stdenv, fetchFromGitHub, cmake, llvmPackages }:
+
+stdenv.mkDerivation rec {
+  pname = "luau";
+  version = "614";
+
+  src = fetchFromGitHub {
+    owner = "luau-lang";
+    repo = "luau";
+    rev = version;
+    hash = "sha256-pM+KSb5jsoPLu2paQYNSdqly0ndbw98Sj2dvMZ7XqhQ=";
+  };
+
+  nativeBuildInputs = [ cmake ];
+
+  buildInputs = lib.optionals stdenv.cc.isClang [ llvmPackages.libunwind ];
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 -t $out/bin luau
+    install -Dm755 -t $out/bin luau-analyze
+
+    runHook postInstall
+  '';
+
+  doCheck = true;
+
+  checkPhase = ''
+    runHook preCheck
+
+    ./Luau.UnitTest
+    ./Luau.Conformance
+
+    runHook postCheck
+  '';
+
+  meta = with lib; {
+    description = "A fast, small, safe, gradually typed embeddable scripting language derived from Lua";
+    homepage = "https://luau-lang.org/";
+    changelog = "https://github.com/luau-lang/luau/releases/tag/${version}";
+    license = licenses.mit;
+    platforms = platforms.all;
+    maintainers = [ maintainers.marsam ];
+    mainProgram = "luau";
+  };
+}