1 files changed, 39 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/development/interpreters/groovy/default.nix b/nixpkgs/pkgs/development/interpreters/groovy/default.nix
new file mode 100644
index 000000000000..97e997bdd693
--- /dev/null
+++ b/nixpkgs/pkgs/development/interpreters/groovy/default.nix
@@ -0,0 +1,39 @@
+{ stdenv, fetchurl, unzip, which, makeWrapper, jdk }:
+
+# at runtime, need jdk
+
+stdenv.mkDerivation rec {
+  pname = "groovy";
+  version = "3.0.3";
+
+  src = fetchurl {
+    url = "http://dl.bintray.com/groovy/maven/apache-groovy-binary-${version}.zip";
+    sha256 = "0xdm70b61pdj8z3g08az16y9b6cpz5hv7iwvwfyfyxrjdi47h419";
+  };
+
+  buildInputs = [ unzip makeWrapper ];
+
+  installPhase = ''
+    mkdir -p $out
+    mkdir -p $out/share/doc/groovy
+    rm bin/*.bat
+    mv {bin,conf,grooid,indy,lib} $out
+    mv {licenses,LICENSE,NOTICE} $out/share/doc/groovy
+
+    sed -i 's#which#${which}/bin/which#g' $out/bin/startGroovy
+
+    for p in grape java2groovy groovy{,doc,c,sh,Console}; do
+      wrapProgram $out/bin/$p \
+            --set JAVA_HOME "${jdk}" \
+            --prefix PATH ":" "${jdk}/bin"
+    done
+  '';
+
+  meta = with stdenv.lib; {
+    description = "An agile dynamic language for the Java Platform";
+    homepage = "http://groovy-lang.org/";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ pSub ];
+    platforms = with platforms; unix;
+  };
+}