2 files changed, 84 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/desktops/pantheon/third-party/pantheon-tweaks/default.nix b/nixpkgs/pkgs/desktops/pantheon/third-party/pantheon-tweaks/default.nix
new file mode 100644
index 000000000000..af6bf54fd715
--- /dev/null
+++ b/nixpkgs/pkgs/desktops/pantheon/third-party/pantheon-tweaks/default.nix
@@ -0,0 +1,71 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, nix-update-script
+, meson
+, ninja
+, pkg-config
+, python3
+, vala
+, gtk3
+, libgee
+, pantheon
+}:
+
+stdenv.mkDerivation rec {
+  pname = "pantheon-tweaks";
+  version = "1.0.3";
+
+  src = fetchFromGitHub {
+    owner = "pantheon-tweaks";
+    repo = pname;
+    rev = version;
+    sha256 = "sha256-Pn/MIJ/WS/TY5bemM77B37E0KFRlDUfrOl1XS2yJlGk=";
+  };
+
+  patches = [
+    ./fix-paths.patch
+  ];
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    python3
+    vala
+  ];
+
+  buildInputs = [
+    gtk3
+    libgee
+  ] ++ (with pantheon; [
+    elementary-files # settings schemas
+    elementary-terminal # settings schemas
+    granite
+    switchboard
+  ]);
+
+  postPatch = ''
+    chmod +x meson/post_install.py
+    patchShebangs meson/post_install.py
+  '';
+
+  passthru = {
+    updateScript = nix-update-script {
+      attrPath = pname;
+    };
+  };
+
+  meta = with lib; {
+    description = "Unofficial system settings panel for Pantheon";
+    longDescription = ''
+      Unofficial system settings panel for Pantheon
+      that lets you easily and safely customise your desktop's appearance.
+      Use programs.pantheon-tweaks.enable to add this to your switchboard.
+    '';
+    homepage = "https://github.com/pantheon-tweaks/pantheon-tweaks";
+    license = licenses.gpl3Plus;
+    platforms = platforms.linux;
+    maintainers = teams.pantheon.members;
+  };
+}
diff --git a/nixpkgs/pkgs/desktops/pantheon/third-party/pantheon-tweaks/fix-paths.patch b/nixpkgs/pkgs/desktops/pantheon/third-party/pantheon-tweaks/fix-paths.patch
new file mode 100644
index 000000000000..b2e0e0a7b4c8
--- /dev/null
+++ b/nixpkgs/pkgs/desktops/pantheon/third-party/pantheon-tweaks/fix-paths.patch
@@ -0,0 +1,13 @@
+diff --git a/src/Settings/ThemeSettings.vala b/src/Settings/ThemeSettings.vala
+index 589121b..8e9c81e 100644
+--- a/src/Settings/ThemeSettings.vala
++++ b/src/Settings/ThemeSettings.vala
+@@ -29,7 +29,7 @@ public class PantheonTweaks.ThemeSettings {
+         var themes = new Gee.ArrayList<string> ();
+ 
+         string[] dirs = {
+-            "/usr/share/" + path + "/",
++            "/run/current-system/sw/share/" + path + "/",
+             Environment.get_home_dir () + "/." + path + "/",
+             Environment.get_home_dir () + "/.local/share/" + path + "/"};
+