1 files changed, 70 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/desktops/pantheon/artwork/elementary-icon-theme/default.nix b/nixpkgs/pkgs/desktops/pantheon/artwork/elementary-icon-theme/default.nix
new file mode 100644
index 000000000000..55935b2ee0e0
--- /dev/null
+++ b/nixpkgs/pkgs/desktops/pantheon/artwork/elementary-icon-theme/default.nix
@@ -0,0 +1,70 @@
+{ lib, stdenv
+, fetchFromGitHub
+, nix-update-script
+, pantheon
+, meson
+, python3
+, ninja
+, hicolor-icon-theme
+, gtk3
+, xorg
+, librsvg
+}:
+
+stdenv.mkDerivation rec {
+  pname = "elementary-icon-theme";
+  version = "5.3.1";
+
+  repoName = "icons";
+
+  src = fetchFromGitHub {
+    owner = "elementary";
+    repo = repoName;
+    rev = version;
+    sha256 = "sha256-6XFzjpuHpGIZ+azkPuFcSF7p66sDonwLwjvlNBZDRmc=";
+  };
+
+  passthru = {
+    updateScript = nix-update-script {
+      attrPath = "pantheon.${pname}";
+    };
+  };
+
+  nativeBuildInputs = [
+    gtk3
+    librsvg
+    meson
+    ninja
+    python3
+    xorg.xcursorgen
+  ];
+
+  propagatedBuildInputs = [
+    hicolor-icon-theme
+  ];
+
+  dontDropIconThemeCache = true;
+
+  mesonFlags = [
+    "-Dvolume_icons=false" # Tries to install some icons to /
+    "-Dpalettes=false" # Don't install gimp and inkscape palette files
+  ];
+
+  postPatch = ''
+    chmod +x meson/symlink.py
+    patchShebangs meson/symlink.py
+  '';
+
+  postFixup = "gtk-update-icon-cache $out/share/icons/elementary";
+
+  meta = with lib; {
+    description = "Named, vector icons for elementary OS";
+    longDescription = ''
+      An original set of vector icons designed specifically for elementary OS and its desktop environment: Pantheon.
+    '';
+    homepage = "https://github.com/elementary/icons";
+    license = licenses.gpl3;
+    platforms = platforms.linux;
+    maintainers = pantheon.maintainers;
+  };
+}