11 files changed, 488 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/by-name/sn/sn0int/package.nix b/nixpkgs/pkgs/by-name/sn/sn0int/package.nix
new file mode 100644
index 000000000000..2410fa0cc230
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/sn/sn0int/package.nix
@@ -0,0 +1,60 @@
+{ lib
+, fetchFromGitHub
+, rustPlatform
+, libseccomp
+, libsodium
+, pkg-config
+, pkgs
+, sqlite
+, stdenv
+, installShellFiles
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "sn0int";
+  version = "0.26.0";
+
+  src = fetchFromGitHub {
+    owner = "kpcyrd";
+    repo = pname;
+    rev = "refs/tags/v${version}";
+    hash = "sha256-ze4OFKUuc/t6tXgmoWFFDjpAQraSY6RIekkcDBctPJo=";
+  };
+
+  cargoHash = "sha256-PAKmoifqB1YC02fVF2SRbXAAGrMcB+Wlvr3FwuqmPVU=";
+
+  nativeBuildInputs = [
+    pkg-config
+    installShellFiles
+  ];
+
+  buildInputs = [
+    libsodium
+    sqlite
+  ] ++ lib.optionals stdenv.isLinux [
+    libseccomp
+  ] ++ lib.optionals stdenv.isDarwin [
+    pkgs.darwin.apple_sdk.frameworks.Security
+  ];
+
+  # One of the dependencies (chrootable-https) tries to read "/etc/resolv.conf"
+  # in "checkPhase", hence fails in sandbox of "nix".
+  doCheck = false;
+
+  postInstall = ''
+    installShellCompletion --cmd sn0int \
+      --bash <($out/bin/sn0int completions bash) \
+      --fish <($out/bin/sn0int completions fish) \
+      --zsh  <($out/bin/sn0int completions zsh)
+  '';
+
+  meta = with lib; {
+    description = "Semi-automatic OSINT framework and package manager";
+    homepage = "https://github.com/kpcyrd/sn0int";
+    changelog = "https://github.com/kpcyrd/sn0int/releases/tag/v${version}";
+    license = with licenses; [ gpl3Plus ];
+    maintainers = with maintainers; [ fab xrelkd ];
+    platforms = platforms.linux ++ platforms.darwin;
+    mainProgram = "sn0int";
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/sn/snekim/lock.json b/nixpkgs/pkgs/by-name/sn/snekim/lock.json
new file mode 100644
index 000000000000..d381dd989411
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/sn/snekim/lock.json
@@ -0,0 +1,40 @@
+{
+  "depends": [
+    {
+      "method": "fetchzip",
+      "packages": [
+        "nimraylib_now"
+      ],
+      "path": "/nix/store/vcq7r99jnqh6cj6cdd5227pymk9rnk7g-source",
+      "ref": "v0.15.0",
+      "rev": "59154abcbc4cf89b4c674f402db026dea216da7b",
+      "sha256": "0b6rn9y1d5fpkdf16g0bjrkj39sq1iyq0zlkwi1xmsbq681j5inp",
+      "srcDir": "src",
+      "url": "https://github.com/greenfork/nimraylib_now/archive/59154abcbc4cf89b4c674f402db026dea216da7b.tar.gz"
+    },
+    {
+      "method": "fetchzip",
+      "packages": [
+        "regex"
+      ],
+      "path": "/nix/store/vfs4ysdw2kvyp18jwpbvb9wfh1ajz0a9-source",
+      "ref": "v0.23.0",
+      "rev": "577c4ec3b235c5fd2653a9c86cbc4a576cfc0869",
+      "sha256": "0401f9m2m2h6bikl3hffyhaw5fc2nbjdf5mj4z9wckmm9lx9hpkl",
+      "srcDir": "src",
+      "url": "https://github.com/nitely/nim-regex/archive/577c4ec3b235c5fd2653a9c86cbc4a576cfc0869.tar.gz"
+    },
+    {
+      "method": "fetchzip",
+      "packages": [
+        "unicodedb"
+      ],
+      "path": "/nix/store/wpilzdf8vdwp7w129yrl821p9qvl3ky3-source",
+      "ref": "0.12.0",
+      "rev": "b055310c08db8f879057b4fec15c8301ee93bb2a",
+      "sha256": "0w77h75vrgp6jiq4dd9i2m4za2cf8qhjkz2wlxiz27yn2isjrndy",
+      "srcDir": "src",
+      "url": "https://github.com/nitely/nim-unicodedb/archive/b055310c08db8f879057b4fec15c8301ee93bb2a.tar.gz"
+    }
+  ]
+}
diff --git a/nixpkgs/pkgs/by-name/sn/snekim/package.nix b/nixpkgs/pkgs/by-name/sn/snekim/package.nix
new file mode 100644
index 000000000000..e041c1f0e314
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/sn/snekim/package.nix
@@ -0,0 +1,31 @@
+{ lib, buildNimPackage, fetchFromGitea, raylib }:
+
+buildNimPackage (finalAttrs: {
+  pname = "snekim";
+  version = "1.2.0";
+
+  src = fetchFromGitea {
+    domain = "codeberg.org";
+    owner = "annaaurora";
+    repo = "snekim";
+    rev = "v${finalAttrs.version}";
+    sha256 = "sha256-Qgvq4CkGvNppYFpITCCifOHtVQYRQJPEK3rTJXQkTvI=";
+  };
+
+  strictDeps = true;
+  lockFile = ./lock.json;
+
+  nimFlags = [ "-d:nimraylib_now_shared" ];
+
+  postInstall = ''
+    install -D snekim.desktop -t $out/share/applications
+    install -D icons/hicolor/48x48/snekim.svg -t $out/share/icons/hicolor/48x48/apps
+  '';
+
+  meta = {
+    homepage = "https://codeberg.org/annaaurora/snekim";
+    description = "A simple implementation of the classic snake game";
+    license = lib.licenses.lgpl3Only;
+    maintainers = [ lib.maintainers.annaaurora ];
+  };
+})
diff --git a/nixpkgs/pkgs/by-name/sn/snicat/deps.nix b/nixpkgs/pkgs/by-name/sn/snicat/deps.nix
new file mode 100644
index 000000000000..dca575f88344
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/sn/snicat/deps.nix
@@ -0,0 +1,12 @@
+[
+  {
+    goPackagePath = "github.com/therootcompany/sclient";
+    fetch = {
+      type = "FromGitHub";
+      owner = "therootcompany";
+      repo = "sclient";
+      rev = "v1.5.0";
+      sha256 = "sha256-NAFTOx2sm92K+d746Z5UpB1HGsJI6cJgmh+YTyVkJ0w=";
+    };
+  }
+]
diff --git a/nixpkgs/pkgs/by-name/sn/snicat/package.nix b/nixpkgs/pkgs/by-name/sn/snicat/package.nix
new file mode 100644
index 000000000000..bbc3fded5b2f
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/sn/snicat/package.nix
@@ -0,0 +1,37 @@
+{ lib
+, buildGoPackage
+, fetchFromGitHub
+}:
+buildGoPackage rec {
+  pname = "snicat";
+  version = "0.0.1";
+
+  src = fetchFromGitHub {
+    owner = "CTFd";
+    repo = "snicat";
+    rev = version;
+    hash = "sha256-fFlTBOz127le2Y7F9KKhbcldcyFEpAU5QiJ4VCAPs9Y=";
+  };
+
+  goPackagePath = "github.com/CTFd/snicat";
+
+  goDeps = ./deps.nix;
+
+  ldflags = [ "-s" "-w" "-X main.version=v${version}" ];
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm555 go/bin/snicat $out/bin/sc
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "TLS & SNI aware netcat";
+    homepage = "https://github.com/CTFd/snicat";
+    license = licenses.asl20;
+    mainProgram = "sc";
+    maintainers = with maintainers; [ felixalbrigtsen ];
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/sn/sniffglue/package.nix b/nixpkgs/pkgs/by-name/sn/sniffglue/package.nix
new file mode 100644
index 000000000000..eb7cff5b7a8e
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/sn/sniffglue/package.nix
@@ -0,0 +1,39 @@
+{ lib
+, fetchFromGitHub
+, libpcap
+, libseccomp
+, pkg-config
+, rustPlatform
+, stdenv
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "sniffglue";
+  version = "0.16.0";
+
+  src = fetchFromGitHub {
+    owner = "kpcyrd";
+    repo = pname;
+    rev = "v${version}";
+    hash = "sha256-MOw0WBdpo6dYXsjbUrqoIJl/sjQ4wSAcm4dPxDgTYgY=";
+  };
+
+  cargoHash = "sha256-vnfviiXJ4L/j5M3N+LegOIvLuD6vYJB1QeBgZJVfDnI=";
+
+  nativeBuildInputs = [ pkg-config ];
+
+  buildInputs = [
+    libpcap
+  ] ++ lib.optionals stdenv.isLinux [
+    libseccomp
+  ];
+
+  meta = with lib; {
+    description = "Secure multithreaded packet sniffer";
+    homepage = "https://github.com/kpcyrd/sniffglue";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ xrelkd ];
+    platforms = platforms.linux ++ platforms.darwin;
+    mainProgram = "sniffglue";
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/sn/snippetexpander/package.nix b/nixpkgs/pkgs/by-name/sn/snippetexpander/package.nix
new file mode 100644
index 000000000000..1f5f3a954ec0
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/sn/snippetexpander/package.nix
@@ -0,0 +1,47 @@
+{ lib
+, buildGoModule
+, fetchFromSourcehut
+, scdoc
+, installShellFiles
+, snippetexpanderd
+}:
+
+buildGoModule rec {
+  inherit (snippetexpanderd) src version;
+
+  pname = "snippetexpander";
+
+  vendorHash = "sha256-wSAho59yxcXTu1zQ5x783HT4gtfSM4GdsOEeC1wfHhE=";
+
+  proxyVendor = true;
+
+  modRoot = "cmd/snippetexpander";
+
+  nativeBuildInputs = [
+    scdoc
+    installShellFiles
+  ];
+
+  buildInputs = [
+    snippetexpanderd
+  ];
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  postInstall = ''
+    make man
+    installManPage snippetexpander.1
+  '';
+
+  meta = with lib; {
+    description = "Your little expandable text snippet helper CLI";
+    homepage = "https://snippetexpander.org";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ ianmjones ];
+    platforms = platforms.linux;
+    mainProgram = "snippetexpander";
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/sn/snippetexpanderd/package.nix b/nixpkgs/pkgs/by-name/sn/snippetexpanderd/package.nix
new file mode 100644
index 000000000000..308803ad9eec
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/sn/snippetexpanderd/package.nix
@@ -0,0 +1,63 @@
+{ lib
+, stdenv
+, buildGoModule
+, fetchFromSourcehut
+, pkg-config
+, makeWrapper
+, scdoc
+, installShellFiles
+, xorg
+, gtk3
+}:
+
+buildGoModule rec {
+  pname = "snippetexpanderd";
+  version = "1.0.1";
+
+  src = fetchFromSourcehut {
+    owner = "~ianmjones";
+    repo = "snippetexpander";
+    rev = "v${version}";
+    hash = "sha256-y3TJ+L3kXYfZFzAD1vmhvP6Yarctu5LHq/74005h8sI=";
+  };
+
+  vendorHash = "sha256-QX8HI8I1ZJI6HJ1sl86OiJ4nxwFAjHH8h1zB9ASJaQs=";
+
+  modRoot = "cmd/snippetexpanderd";
+
+  nativeBuildInputs = [
+    pkg-config
+    makeWrapper
+    scdoc
+    installShellFiles
+  ];
+
+  buildInputs = [
+    xorg.libX11
+    gtk3
+  ];
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  postInstall = ''
+    make man
+    installManPage snippetexpanderd.1 snippetexpander-placeholders.5
+  '';
+
+  postFixup = ''
+    wrapProgram $out/bin/snippetexpanderd \
+      --prefix LD_LIBRARY_PATH : ${lib.makeLibraryPath [ xorg.libX11 ]}
+  '';
+
+  meta = with lib; {
+    description = "Your little expandable text snippet helper daemon";
+    homepage = "https://snippetexpander.org";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ ianmjones ];
+    platforms = platforms.linux;
+    mainProgram = "snippetexpanderd";
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/sn/snippetexpandergui/package.nix b/nixpkgs/pkgs/by-name/sn/snippetexpandergui/package.nix
new file mode 100644
index 000000000000..1ce5f5d9cbe5
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/sn/snippetexpandergui/package.nix
@@ -0,0 +1,70 @@
+{ lib
+, buildGoModule
+, fetchFromSourcehut
+, makeWrapper
+, wails
+, scdoc
+, installShellFiles
+, xorg
+, gtk3
+, webkitgtk
+, gsettings-desktop-schemas
+, snippetexpanderd
+}:
+
+buildGoModule rec {
+  inherit (snippetexpanderd) src version;
+
+  pname = "snippetexpandergui";
+
+  vendorHash = "sha256-iZfZdT8KlfZMVLQcYmo6EooIdsSGrpO/ojwT9Ft1GQI=";
+
+  proxyVendor = true;
+
+  modRoot = "cmd/snippetexpandergui";
+
+  nativeBuildInputs = [
+    makeWrapper
+    wails
+    scdoc
+    installShellFiles
+  ];
+
+  buildInputs = [
+    xorg.libX11
+    gtk3
+    webkitgtk
+    gsettings-desktop-schemas
+    snippetexpanderd
+  ];
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  tags = [
+    "desktop"
+    "production"
+  ];
+
+  postInstall = ''
+    mv build/linux/share $out/share
+    make man
+    installManPage snippetexpandergui.1
+  '';
+
+  postFixup = ''
+    wrapProgram $out/bin/snippetexpandergui \
+      --prefix XDG_DATA_DIRS : ${gsettings-desktop-schemas}/share/gsettings-schemas/${gsettings-desktop-schemas.name}:${gtk3}/share/gsettings-schemas/${gtk3.name}
+  '';
+
+  meta = with lib; {
+    description = "Your little expandable text snippet helper GUI";
+    homepage = "https://snippetexpander.org";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ ianmjones ];
+    platforms = platforms.linux;
+    mainProgram = "snippetexpandergui";
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/sn/snippetexpanderx/package.nix b/nixpkgs/pkgs/by-name/sn/snippetexpanderx/package.nix
new file mode 100644
index 000000000000..3c91adbbbc0c
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/sn/snippetexpanderx/package.nix
@@ -0,0 +1,64 @@
+{ lib
+, stdenv
+, fetchFromSourcehut
+, pkg-config
+, vala
+, wrapGAppsHook
+, installShellFiles
+, scdoc
+, at-spi2-atk
+, at-spi2-core
+, dbus
+, gtk3
+, ibus
+, libgee
+, xorg
+, snippetexpanderd
+}:
+
+stdenv.mkDerivation rec {
+  inherit (snippetexpanderd) src version;
+
+  pname = "snippetexpanderx";
+
+  sourceRoot = "source/cmd/snippetexpanderx";
+
+  nativeBuildInputs = [
+    pkg-config
+    vala
+    wrapGAppsHook
+    installShellFiles
+    scdoc
+  ];
+
+  buildInputs = [
+    at-spi2-atk
+    at-spi2-core
+    dbus
+    gtk3
+    ibus
+    libgee
+    xorg.libX11
+    snippetexpanderd
+  ];
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/bin
+    install -m555 snippetexpanderx $out/bin/
+    installManPage snippetexpanderx.1
+    runHook postInstall
+  '';
+
+  # There are no tests.
+  doCheck = false;
+
+  meta = with lib; {
+    description = "Your little expandable text snippet helper auto expander daemon";
+    homepage = "https://snippetexpander.org";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ ianmjones ];
+    platforms = platforms.linux;
+    mainProgram = "snippetexpanderx";
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/sn/snowmachine/package.nix b/nixpkgs/pkgs/by-name/sn/snowmachine/package.nix
new file mode 100644
index 000000000000..a6d3aedf0b41
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/sn/snowmachine/package.nix
@@ -0,0 +1,25 @@
+{ python3Packages, lib, fetchPypi }:
+
+python3Packages.buildPythonApplication rec {
+  pname = "snowmachine";
+  version = "2.0.1";
+  pyproject = true;
+
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256:119e6da12f430af1519f1a9f091b77b7676c7a9dbeaab6616cb196fe793d8e61";
+  };
+
+  propagatedBuildInputs = with python3Packages; [ click colorama hatchling ];
+
+  doCheck = false;
+  pythonImportsCheck = [ "snowmachine" ];
+
+  meta = with lib; {
+    description = "A python script that will make your terminal snow";
+    homepage = "https://github.com/sontek/snowmachine";
+    mainProgram = "snowmachine";
+    license = with licenses; [ bsd3 ];
+    maintainers = with maintainers; [ djanatyn sontek ];
+  };
+}