17 files changed, 882 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/by-name/mo/modern-cpp-kafka/package.nix b/nixpkgs/pkgs/by-name/mo/modern-cpp-kafka/package.nix
new file mode 100644
index 000000000000..7986c63aab53
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/mo/modern-cpp-kafka/package.nix
@@ -0,0 +1,70 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, fetchpatch
+, cmake
+, boost
+, rdkafka
+, gtest
+, rapidjson
+}:
+
+stdenv.mkDerivation rec {
+  pname = "modern-cpp-kafka";
+  version = "2023.03.07";
+
+  src = fetchFromGitHub {
+    repo = "modern-cpp-kafka";
+    owner = "morganstanley";
+    rev = "v${version}";
+    hash = "sha256-7hkwM1YbveQpDRqwMZ3MXM88LTwlAT7uB8NL0t409To=";
+  };
+
+  patches = [
+    (fetchpatch {
+      name = "fix-avoid-overwriting-library-paths.patch";
+      url = "https://github.com/morganstanley/modern-cpp-kafka/pull/221.patch";
+      hash = "sha256-UsQcMvJoRTn5kgXhmXOyqfW3n59kGKO596U2WjtdqAY=";
+    })
+    (fetchpatch {
+      name = "add-pkg-config-cmake-config.patch";
+      url = "https://github.com/morganstanley/modern-cpp-kafka/pull/222.patch";
+      hash = "sha256-OjoSttnpgEwSZjCVKc888xJb5f1Dulu/rQqoGmqXNM4=";
+    })
+    # Fix gcc-13 build failure:
+    #   https://github.com/morganstanley/modern-cpp-kafka/pull/229
+    (fetchpatch {
+      name = "add-pkg-config-cmake-config.patch";
+      url = "https://github.com/morganstanley/modern-cpp-kafka/commit/236f8f91f5c3ad6e1055a6f55cd3aebd218e1226.patch";
+      hash = "sha256-cy568TQUu08sadq79hDz9jMvDqiDjfr+1cLMxFWGm1Q=";
+    })
+  ];
+
+  postPatch = ''
+    # Blanket -Werror tends to fail on minor unrelated warnings.
+    # Currently this fixes gcc-13 build failure.
+    substituteInPlace CMakeLists.txt --replace-fail '"-Werror"' ' '
+  '';
+
+  nativeBuildInputs = [ cmake ];
+  buildInputs = [ boost ];
+  propagatedBuildInputs = [ rdkafka ];
+
+  cmakeFlags = [
+    "-DLIBRDKAFKA_INCLUDE_DIR=${rdkafka.out}/include"
+    "-DGTEST_LIBRARY_DIR=${gtest.out}/lib"
+    "-DGTEST_INCLUDE_DIR=${gtest.dev}/include"
+    "-DRAPIDJSON_INCLUDE_DIRS=${rapidjson.out}/include"
+    "-DCMAKE_CXX_FLAGS=-Wno-uninitialized"
+  ];
+
+  checkInputs = [ gtest rapidjson ];
+
+  meta = with lib; {
+    description = "A C++ API for Kafka clients (i.e. KafkaProducer, KafkaConsumer, AdminClient)";
+    homepage = "https://github.com/morganstanley/modern-cpp-kafka";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ ditsuke ];
+    platforms = platforms.unix;
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/mo/modprobed-db/package.nix b/nixpkgs/pkgs/by-name/mo/modprobed-db/package.nix
new file mode 100644
index 000000000000..2a307aeb832c
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/mo/modprobed-db/package.nix
@@ -0,0 +1,50 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, pkg-config
+, libevdev
+, kmod
+, bash
+, installShellFiles
+}:
+let
+  pname = "modprobed-db";
+  version = "2.46";
+in
+stdenv.mkDerivation {
+  inherit pname version;
+
+  src = fetchFromGitHub {
+    owner = "graysky2";
+    repo = "modprobed-db";
+    rev = "v${version}";
+    hash = "sha256-GQME5CAZsGVHSPowKQMyUR7OjHeFZi/5YcWFUT9L/AQ=";
+  };
+
+  strictDeps = true;
+  nativeBuildInputs = [ pkg-config installShellFiles ];
+  buildInputs = [ kmod libevdev bash ];
+
+  installFlags = [
+    "PREFIX=$(out)"
+    "INITDIR_SYSTEMD=$(out)/lib/systemd/user"
+  ];
+
+  postPatch = ''
+    substituteInPlace ./common/modprobed-db.in \
+      --replace "/usr/share" "$out/share"
+  '';
+
+  postInstall = ''
+    installShellCompletion --zsh common/zsh-completion
+  '';
+
+  meta = {
+    homepage = "https://github.com/graysky2/modprobed-db";
+    description = "Useful utility for users wishing to build a minimal kernel via a make localmodconfig";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ NotAShelf ];
+    mainProgram = "modprobed-db";
+    platforms = lib.platforms.linux;
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/mo/moe/package.nix b/nixpkgs/pkgs/by-name/mo/moe/package.nix
new file mode 100644
index 000000000000..766d80215020
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/mo/moe/package.nix
@@ -0,0 +1,51 @@
+{ lib
+, stdenv
+, fetchurl
+, lzip
+, ncurses
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "moe";
+  version = "1.14";
+
+  src = fetchurl {
+    url = "mirror://gnu/moe/moe-${finalAttrs.version}.tar.lz";
+    hash = "sha256-9Lq9bOCuGVFvmDRU+yDTLf9xrTFjN6xr+TpCpf8gnJ0=";
+  };
+
+  prePatch = ''
+    substituteInPlace window_vector.cc --replace \
+      "insert( 0U, 1," \
+      "insert( 0U, 1U,"
+  '';
+
+  nativeBuildInputs = [
+    lzip
+  ];
+
+  buildInputs = [
+    ncurses
+  ];
+
+  strictDeps = true;
+
+  meta = {
+    homepage = "https://www.gnu.org/software/moe/";
+    description = "A small, 8-bit clean editor";
+    longDescription = ''
+      GNU moe is a powerful, 8-bit clean, console text editor for ISO-8859 and
+      ASCII character encodings. It has a modeless, user-friendly interface,
+      online help, multiple windows, unlimited undo/redo capability, unlimited
+      line length, unlimited buffers, global search/replace (on all buffers at
+      once), block operations, automatic indentation, word wrapping, file name
+      completion, directory browser, duplicate removal from prompt histories,
+      delimiter matching, text conversion from/to UTF-8, romanization, etc.
+    '';
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [ AndersonTorres ];
+    platforms = lib.platforms.unix;
+    mainProgram = "moe";
+  };
+})
+# TODO: a configurable, global moerc file
diff --git a/nixpkgs/pkgs/by-name/mo/mommy/package.nix b/nixpkgs/pkgs/by-name/mo/mommy/package.nix
new file mode 100644
index 000000000000..8d2187068514
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/mo/mommy/package.nix
@@ -0,0 +1,58 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, makeWrapper
+, writeText
+, shellspec
+, fetchpatch
+  # usage:
+  # pkgs.mommy.override {
+  #  mommySettings.sweetie = "catgirl";
+  # }
+  #
+  # $ mommy
+  # who's my good catgirl~
+, mommySettings ? null
+}:
+
+let
+  variables = lib.mapAttrs'
+    (name: value: lib.nameValuePair "MOMMY_${lib.toUpper name}" value)
+    mommySettings;
+  configFile = writeText "mommy-config" (lib.toShellVars variables);
+in
+stdenv.mkDerivation rec {
+  pname = "mommy";
+  version = "1.5.0";
+
+  src = fetchFromGitHub {
+    owner = "FWDekker";
+    repo = pname;
+    rev = "v${version}";
+    hash = "sha256-kNhoEIzrPjCe6RA/GHFB/NtKjYFByM5TpxAwCLo5TDo=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+  nativeCheckInputs = [ shellspec ];
+  installFlags = [ "prefix=$(out)" ];
+
+  doCheck = true;
+  checkTarget = "test/unit";
+
+  postInstall = ''
+    ${lib.optionalString (mommySettings != null) ''
+      wrapProgram $out/bin/mommy \
+        --set-default MOMMY_OPT_CONFIG_FILE "${configFile}"
+    ''}
+  '';
+
+  meta = with lib; {
+    description = "mommy's here to support you, in any shell, on any system~ ❤️";
+    homepage = "https://github.com/FWDekker/mommy";
+    changelog = "https://github.com/FWDekker/mommy/blob/v${version}/CHANGELOG.md";
+    license = licenses.unlicense;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ ckie ];
+    mainProgram = "mommy";
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/mo/monaspace/package.nix b/nixpkgs/pkgs/by-name/mo/monaspace/package.nix
new file mode 100644
index 000000000000..a27be47afa66
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/mo/monaspace/package.nix
@@ -0,0 +1,56 @@
+{ lib
+, stdenvNoCC
+, fetchzip
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "monaspace";
+  version = "1.000";
+
+  src = fetchzip {
+    url = "https://github.com/githubnext/monaspace/releases/download/v${finalAttrs.version}/monaspace-v${finalAttrs.version}.zip";
+    stripRoot = false;
+    hash = "sha256-H8NOS+pVkrY9DofuJhPR2OlzkF4fMdmP2zfDBfrk83A=";
+  };
+
+  outputs = [ "out" "woff" ];
+
+  installPhase = ''
+    runHook preInstall
+
+    pushd monaspace-v${finalAttrs.version}/fonts/
+    install -Dm644 otf/*.otf -t $out/share/fonts/opentype
+    install -Dm644 variable/*.ttf -t $out/share/fonts/truetype
+    install -Dm644 webfonts/*.woff -t $woff/share/fonts/woff
+    popd
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "An innovative superfamily of fonts for code";
+    longDescription = ''
+      Since the earliest days of the teletype machine, code has been set in
+      monospaced type — letters, on a grid. Monaspace is a new type system that
+      advances the state of the art for the display of code on screen.
+
+      Every advancement in the technology of computing has been accompanied by
+      advancements to the display and editing of code. CRTs made screen editors
+      possible. The advent of graphical user interfaces gave rise to integrated
+      development environments.
+
+      Even today, we still have limited options when we want to layer additional
+      meaning on top of code. Syntax highlighting was invented in 1982 to help
+      children to code in BASIC. But beyond colors, most editors must
+      communicate with developers through their interfaces — hovers, underlines,
+      and other graphical decorations.
+
+      Monaspace offers a more expressive palette for code and the tools we use
+      to work with it.
+    '';
+    homepage = "https://monaspace.githubnext.com/";
+    license = lib.licenses.ofl;
+    maintainers = with lib.maintainers; [ AndersonTorres ];
+    platforms = lib.platforms.all;
+  };
+})
diff --git a/nixpkgs/pkgs/by-name/mo/moneydance/package.nix b/nixpkgs/pkgs/by-name/mo/moneydance/package.nix
new file mode 100644
index 000000000000..5222684f706b
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/mo/moneydance/package.nix
@@ -0,0 +1,52 @@
+{ lib, stdenv, fetchzip, makeWrapper, openjdk21, openjfx21, jvmFlags ? [ ] }:
+let jdk = openjdk21.override { enableJavaFX = true; };
+in stdenv.mkDerivation (finalAttrs: {
+  pname = "moneydance";
+  version = "2023.3_5064";
+
+  src = fetchzip {
+    url = "https://infinitekind.com/stabledl/${finalAttrs.version}/moneydance-linux.tar.gz";
+    hash = "sha256-jHr1V/gV1seenw2Q0/G405lTiabEYEsOS8p/XyByrtM=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+  buildInputs = [ jdk openjfx21 ];
+
+  # Note the double escaping in the call to makeWrapper. The escapeShellArgs
+  # call quotes each element of the flags list as a word[1] and returns a
+  # space-separated result; the escapeShellArg call quotes that result as a
+  # single word to pass to --add-flags. The --add-flags implementation[2]
+  # loops over the words in its argument.
+  #
+  # 1. https://www.gnu.org/software/bash/manual/html_node/Word-Splitting.html
+  # 2. https://github.com/NixOS/nixpkgs/blob/master/pkgs/build-support/setup-hooks/make-wrapper.sh
+  installPhase = let
+    finalJvmFlags = [
+      "-client"
+      "--add-modules"
+      "javafx.swing,javafx.controls,javafx.graphics"
+      "-classpath"
+      "${placeholder "out"}/libexec/*"
+    ] ++ jvmFlags ++ [ "Moneydance" ];
+  in ''
+    runHook preInstall
+
+    mkdir -p $out/libexec $out/bin
+    cp -p $src/lib/* $out/libexec/
+    makeWrapper ${jdk}/bin/java $out/bin/moneydance \
+      --add-flags ${lib.escapeShellArg (lib.escapeShellArgs finalJvmFlags)}
+
+    runHook postInstall
+  '';
+
+  passthru = { inherit jdk; };
+
+  meta = {
+    homepage = "https://infinitekind.com/moneydance";
+    description = "An easy to use and full-featured personal finance app that doesn't compromise your privacy";
+    sourceProvenance = [ lib.sourceTypes.binaryBytecode ];
+    license = lib.licenses.unfree;
+    platforms = jdk.meta.platforms;
+    maintainers = [ lib.maintainers.lucasbergman ];
+  };
+})
diff --git a/nixpkgs/pkgs/by-name/mo/monophony/package.nix b/nixpkgs/pkgs/by-name/mo/monophony/package.nix
new file mode 100644
index 000000000000..64b86b292171
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/mo/monophony/package.nix
@@ -0,0 +1,68 @@
+{ lib
+, fetchFromGitLab
+, python3Packages
+, wrapGAppsHook4
+, gst_all_1
+, gobject-introspection
+, yt-dlp
+, libadwaita
+, glib-networking
+, nix-update-script
+}:
+python3Packages.buildPythonApplication rec {
+  pname = "monophony";
+  version = "2.7.0";
+  format = "other";
+
+  sourceRoot = "${src.name}/source";
+  src = fetchFromGitLab {
+    owner = "zehkira";
+    repo = "monophony";
+    rev = "v${version}";
+    hash = "sha256-uOmaTkjlfrct8CPqKcTTTqmURVncPZm4fXZYW+yZUf8=";
+  };
+
+  pythonPath = with python3Packages; [
+    mpris-server
+    pygobject3
+    ytmusicapi
+  ];
+
+  nativeBuildInputs = [
+    python3Packages.nuitka
+    gobject-introspection
+    wrapGAppsHook4
+  ];
+
+  buildInputs = [
+    libadwaita
+    # needed for gstreamer https
+    glib-networking
+  ] ++ (with gst_all_1; [
+    gst-plugins-base
+    gst-plugins-good
+    gstreamer
+  ]);
+
+  installFlags = [ "prefix=$(out)" ];
+
+  preFixup = ''
+    buildPythonPath "$pythonPath"
+    gappsWrapperArgs+=(
+      --prefix PYTHONPATH : "$program_PYTHONPATH"
+      --prefix PATH : "${lib.makeBinPath [yt-dlp]}"
+    )
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = with lib; {
+    homepage = "https://gitlab.com/zehkira/monophony";
+    description = "Linux app for streaming music from YouTube";
+    longDescription = "Monophony is a free and open source Linux app for streaming music from YouTube. It has no ads and does not require an account.";
+    license = licenses.agpl3Plus;
+    mainProgram = "monophony";
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ quadradical ];
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/mo/morewaita-icon-theme/package.nix b/nixpkgs/pkgs/by-name/mo/morewaita-icon-theme/package.nix
new file mode 100644
index 000000000000..be19082d6d29
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/mo/morewaita-icon-theme/package.nix
@@ -0,0 +1,41 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+  gtk3,
+  xdg-utils,
+}:
+stdenvNoCC.mkDerivation rec {
+  pname = "morewaita-icon-theme";
+  version = "45";
+
+  src = fetchFromGitHub {
+    owner = "somepaulo";
+    repo = "MoreWaita";
+    rev = "v${version}";
+    hash = "sha256-UtwigqJjkin53Wg3PU14Rde6V42eKhmP26a3fDpbJ4Y=";
+  };
+
+  nativeBuildInputs = [
+    gtk3
+    xdg-utils
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    install -d $out/share/icons/MoreWaita
+    cp -r . $out/share/icons/MoreWaita
+    gtk-update-icon-cache -f -t $out/share/icons/MoreWaita && xdg-desktop-menu forceupdate
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "An Adwaita style extra icons theme for Gnome Shell";
+    homepage = "https://github.com/somepaulo/MoreWaita";
+    license = with licenses; [ gpl3Only ];
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ pkosel ];
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/mo/mos/package.nix b/nixpkgs/pkgs/by-name/mo/mos/package.nix
new file mode 100644
index 000000000000..a85b77c4f3e0
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/mo/mos/package.nix
@@ -0,0 +1,35 @@
+{ lib
+, stdenvNoCC
+, fetchurl
+, undmg
+}:
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "mos";
+  version = "3.4.1";
+
+  src = fetchurl {
+    url = "https://github.com/Caldis/Mos/releases/download/${finalAttrs.version}/Mos.Versions.${finalAttrs.version}.dmg";
+    sha256 = "38ea33e867815506414323484147b882b6d97df4af9759bca0a64d98c95029b3";
+  };
+  sourceRoot = ".";
+
+  nativeBuildInputs = [
+    undmg
+  ];
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/Applications
+    cp -r *.app $out/Applications
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Smooths scrolling and set mouse scroll directions independently";
+    homepage = "http://mos.caldis.me/";
+    license = licenses.cc-by-nc-40;
+    maintainers = with maintainers; [ ];
+    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
+    platforms = platforms.darwin;
+  };
+})
diff --git a/nixpkgs/pkgs/by-name/mo/mosdepth/lock.json b/nixpkgs/pkgs/by-name/mo/mosdepth/lock.json
new file mode 100644
index 000000000000..32681f3d43c8
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/mo/mosdepth/lock.json
@@ -0,0 +1,64 @@
+{
+  "depends": [
+    {
+      "method": "fetchzip",
+      "packages": [
+        "d4"
+      ],
+      "path": "/nix/store/gc6hspl4p050mrlm3v3gj6pw87rp3awj-source",
+      "ref": "v0.0.3",
+      "rev": "3536104b4070ff617537ef37db7cfbae36909546",
+      "sha256": "12n5snrxha27hz95qq7krgrmip39xvhb400y5b0awnh44gczwn90",
+      "srcDir": "src",
+      "url": "https://github.com/brentp/d4-nim/archive/3536104b4070ff617537ef37db7cfbae36909546.tar.gz"
+    },
+    {
+      "method": "fetchzip",
+      "packages": [
+        "docopt"
+      ],
+      "path": "/nix/store/qdmip0p56pd5ivalp3waaqjkc1xvzaxn-source",
+      "ref": "v0.7.1",
+      "rev": "efaa112b6df172a9168c4eb581ab8dda1fbcfe2a",
+      "sha256": "0v85frvfm5difggs016g8llspsq8kd27lq00sv79v65ih9vlr9r4",
+      "srcDir": "src",
+      "url": "https://github.com/docopt/docopt.nim/archive/efaa112b6df172a9168c4eb581ab8dda1fbcfe2a.tar.gz"
+    },
+    {
+      "method": "fetchzip",
+      "packages": [
+        "hts"
+      ],
+      "path": "/nix/store/k19hyryn922gy9f9xmdrj6i80p1npgk0-source",
+      "ref": "v0.3.25",
+      "rev": "e70f16a008d1c6526fa8c108c73968175505d9d0",
+      "sha256": "1pcvqp9lnsl575f13hf6rxg2pb0lsq6z1wi4pzva5yjv5cmwq3pk",
+      "srcDir": "src",
+      "url": "https://github.com/brentp/hts-nim/archive/e70f16a008d1c6526fa8c108c73968175505d9d0.tar.gz"
+    },
+    {
+      "method": "fetchzip",
+      "packages": [
+        "regex"
+      ],
+      "path": "/nix/store/vfs4ysdw2kvyp18jwpbvb9wfh1ajz0a9-source",
+      "ref": "v0.23.0",
+      "rev": "577c4ec3b235c5fd2653a9c86cbc4a576cfc0869",
+      "sha256": "0401f9m2m2h6bikl3hffyhaw5fc2nbjdf5mj4z9wckmm9lx9hpkl",
+      "srcDir": "src",
+      "url": "https://github.com/nitely/nim-regex/archive/577c4ec3b235c5fd2653a9c86cbc4a576cfc0869.tar.gz"
+    },
+    {
+      "method": "fetchzip",
+      "packages": [
+        "unicodedb"
+      ],
+      "path": "/nix/store/wpilzdf8vdwp7w129yrl821p9qvl3ky3-source",
+      "ref": "0.12.0",
+      "rev": "b055310c08db8f879057b4fec15c8301ee93bb2a",
+      "sha256": "0w77h75vrgp6jiq4dd9i2m4za2cf8qhjkz2wlxiz27yn2isjrndy",
+      "srcDir": "src",
+      "url": "https://github.com/nitely/nim-unicodedb/archive/b055310c08db8f879057b4fec15c8301ee93bb2a.tar.gz"
+    }
+  ]
+}
diff --git a/nixpkgs/pkgs/by-name/mo/mosdepth/package.nix b/nixpkgs/pkgs/by-name/mo/mosdepth/package.nix
new file mode 100644
index 000000000000..dbe5bc87726c
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/mo/mosdepth/package.nix
@@ -0,0 +1,34 @@
+{ lib, buildNimPackage, fetchFromGitHub, pcre, testers }:
+
+buildNimPackage (finalAttrs: {
+  pname = "mosdepth";
+  version = "0.3.7";
+
+  requiredNimVersion = 1;
+
+  src = fetchFromGitHub {
+    owner = "brentp";
+    repo = "mosdepth";
+    rev = "v${finalAttrs.version}";
+    sha256 = "sha256-VyEZNY/P3BfJ3PCRn7R+37XH4gfc9JEOFB0WmrSxpIc=";
+  };
+
+  lockFile = ./lock.json;
+
+  buildInputs = [ pcre ];
+
+  passthru.tests = {
+    version = testers.testVersion {
+      package = finalAttrs.finalPackage;
+    };
+  };
+
+  meta = with lib; {
+    description = "fast BAM/CRAM depth calculation for WGS, exome, or targeted sequencing";
+    mainProgram = "mosdepth";
+    license = licenses.mit;
+    homepage = "https://github.com/brentp/mosdepth";
+    maintainers = with maintainers; [ jbedo ];
+    platforms = platforms.linux;
+  };
+})
diff --git a/nixpkgs/pkgs/by-name/mo/mountpoint-s3/package.nix b/nixpkgs/pkgs/by-name/mo/mountpoint-s3/package.nix
new file mode 100644
index 000000000000..3bd0527c2983
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/mo/mountpoint-s3/package.nix
@@ -0,0 +1,59 @@
+{ lib
+, fetchFromGitHub
+, rustPlatform
+, cmake
+, fuse3
+, pkg-config
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "mountpoint-s3";
+  version = "1.5.0";
+
+  src = fetchFromGitHub {
+    owner = "awslabs";
+    repo = "mountpoint-s3";
+    rev = "v${version}";
+    hash = "sha256-DsxcQ/FEVcrzPyv9LgssNut4XnbU3mPKbuBwQKLiRLA=";
+    fetchSubmodules = true;
+  };
+
+  cargoHash = "sha256-UOQRdSQ/whlOTZL2vaNiIcKB+Zgpk8tbinWBRWPyllc=";
+
+  # thread 'main' panicked at cargo-auditable/src/collect_audit_data.rs:77:9:
+  # cargo metadata failure: error: none of the selected packages contains these features: libfuse3
+  auditable = false;
+
+  nativeBuildInputs = [ cmake pkg-config rustPlatform.bindgenHook ];
+  buildInputs = [ fuse3 ];
+
+  checkFlags = [
+    #thread 's3_crt_client::tests::test_expected_bucket_owner' panicked at mountpoint-s3-client/src/s3_crt_client.rs:1123:47:
+    #Create test client: ProviderFailure(Error(1173, "aws-c-io: AWS_IO_TLS_ERROR_DEFAULT_TRUST_STORE_NOT_FOUND, Default TLS trust store not found on this system. Trusted CA certificates must be installed, or \"override default trust store\" must be used while creating the TLS context."))
+    #
+    "--skip=s3_crt_client::tests::test_expected_bucket_owner"
+    "--skip=s3_crt_client::tests::test_user_agent_with_prefix"
+    "--skip=s3_crt_client::tests::test_user_agent_without_prefix"
+    "--skip=tests::smoke"
+    # fuse module not available on build machine ?
+    #
+    # fuse: device not found, try 'modprobe fuse' first
+    # thread 'unmount_no_send' panicked at vendor/fuser/tests/integration_tests.rs:16:79:
+    # called `Result::unwrap()` on an `Err` value: Os { code: 2, kind: NotFound, message: "No such file or directory" }
+    "--skip=unmount_no_send"
+    # sandbox issue ?
+    #
+    # thread 'mnt::test::mount_unmount' panicked at vendor/fuser/src/mnt/mod.rs:165:57:
+    # called `Result::unwrap()` on an `Err` value: Os { code: 2, kind: NotFound, message: "No such file or directory" }
+    "--skip=mnt::test::mount_unmount"
+    "--skip=test_get_identity_document"
+  ];
+
+  meta = with lib; {
+    homepage = "https://github.com/awslabs/mountpoint-s3";
+    description = "A simple, high-throughput file client for mounting an Amazon S3 bucket as a local file system.";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ lblasc ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/mo/mousam/package.nix b/nixpkgs/pkgs/by-name/mo/mousam/package.nix
new file mode 100644
index 000000000000..256ee99a13be
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/mo/mousam/package.nix
@@ -0,0 +1,58 @@
+{ lib
+, python3Packages
+, fetchFromGitHub
+, meson
+, ninja
+, pkg-config
+, gobject-introspection
+, wrapGAppsHook4
+, desktop-file-utils
+, libadwaita
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "mousam";
+  version = "1.1.0";
+  # built with meson, not a python format
+  format = "other";
+
+  src = fetchFromGitHub {
+    owner = "amit9838";
+    repo = "mousam";
+    rev = "v${version}";
+    hash = "sha256-4NJLJ9aPCufvqZGzqQEjSxryofcg4mwk0UohlgUYcqk=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+    gobject-introspection
+    wrapGAppsHook4
+    desktop-file-utils
+  ];
+
+  buildInputs = [
+    libadwaita
+  ];
+
+  propagatedBuildInputs = with python3Packages; [
+    pygobject3
+    requests
+  ];
+
+  dontWrapGApps = true;
+
+  preFixup = ''
+    makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
+  '';
+
+  meta = with lib; {
+    description = "Beautiful and lightweight weather app based on Python and GTK4";
+    homepage = "https://amit9838.github.io/mousam";
+    license = with licenses; [ gpl3Plus ];
+    mainProgram = "mousam";
+    maintainers = with maintainers; [ aleksana ];
+    platforms = platforms.unix;
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/mo/mouse-actions/package.nix b/nixpkgs/pkgs/by-name/mo/mouse-actions/package.nix
new file mode 100644
index 000000000000..652c5ed4243f
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/mo/mouse-actions/package.nix
@@ -0,0 +1,49 @@
+{ lib
+, fetchFromGitHub
+, rustPlatform
+, pkg-config
+, libX11
+, libXi
+, libXtst
+, libevdev
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "mouse-actions";
+  version = "0.4.4";
+
+  src = fetchFromGitHub {
+    owner = "jersou";
+    repo = "mouse-actions";
+    rev = "v${version}";
+    hash = "sha256-02E4HrKIoBV3qZPVH6Tjz9Bv/mh5C8amO1Ilmd+YO5g=";
+  };
+
+  cargoHash = "sha256-5SUVZlrXIPtlu9KBzucZDCp5t5t8Z4/Nfht2Pw5agVI=";
+
+  buildInputs = [
+    libX11
+    libXi
+    libXtst
+    libevdev
+  ];
+
+  nativeBuildInputs = [
+    pkg-config
+  ];
+
+  postInstall = ''
+    mkdir -p $out/etc/udev/rules.d/
+    echo 'KERNEL=="uinput", SUBSYSTEM=="misc", TAG+="uaccess", OPTIONS+="static_node=uinput"' >> $out/etc/udev/rules.d/80-mouse-actions.rules
+    echo 'KERNEL=="/dev/input/event*", SUBSYSTEM=="misc", TAG+="uaccess", OPTIONS+="static_node=uinput"' >> $out/etc/udev/rules.d/80-mouse-actions.rules
+  '';
+
+  meta = with lib; {
+    description = "Execute commands from mouse events such as clicks/wheel on the side/corners of the screen, or drawing shapes";
+    homepage = "https://github.com/jersou/mouse-actions";
+    license = licenses.mit;
+    maintainers = with maintainers; [ rgri ];
+    mainProgram = "mouse-actions";
+    platforms = platforms.linux;
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/mo/mov-cli/package.nix b/nixpkgs/pkgs/by-name/mo/mov-cli/package.nix
new file mode 100644
index 000000000000..cd6f17f7e7a2
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/mo/mov-cli/package.nix
@@ -0,0 +1,64 @@
+{ lib
+, fetchFromGitHub
+, ffmpeg
+, fzf
+, mpv
+, python3
+}:
+
+let
+  pname = "mov-cli";
+  version = "1.5.7";
+in
+python3.pkgs.buildPythonPackage {
+  inherit pname version;
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "mov-cli";
+    repo = "mov-cli";
+    rev = version;
+    hash = "sha256-OJhZtrSB5rjPY80GkTSU82hkcBgFYpW7Rc24BlBH7CE=";
+  };
+
+  propagatedBuildInputs = with python3.pkgs; [
+    beautifulsoup4
+    click
+    colorama
+    httpx
+    krfzf-py
+    lxml
+    poetry-core
+    pycrypto
+    setuptools
+    six
+    tldextract
+  ];
+
+  nativeBuildInputs = [
+    python3.pkgs.pythonRelaxDepsHook
+  ];
+
+  pythonRelaxDeps = [
+    "httpx"
+    "tldextract"
+  ];
+
+  makeWrapperArgs = let
+    binPath = lib.makeBinPath [
+      ffmpeg
+      fzf
+      mpv
+    ];
+  in [
+    "--prefix PATH : ${binPath}"
+  ];
+
+  meta = with lib; {
+    homepage = "https://github.com/mov-cli/mov-cli";
+    description = "A cli tool to browse and watch movies";
+    license = with lib.licenses; [ gpl3Only ];
+    mainProgram = "mov-cli";
+    maintainers = with lib.maintainers; [ baitinq ];
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/mo/move-mount-beneath/package.nix b/nixpkgs/pkgs/by-name/mo/move-mount-beneath/package.nix
new file mode 100644
index 000000000000..be04c80a1b70
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/mo/move-mount-beneath/package.nix
@@ -0,0 +1,30 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+}:
+
+stdenv.mkDerivation {
+  pname = "move-mount-beneath";
+  version = "unstable-2023-11-26";
+
+  src = fetchFromGitHub {
+    owner = "brauner";
+    repo = "move-mount-beneath";
+    rev = "d3d16c0d7766eb1892fcc24a75f8d35df4b0fe45";
+    hash = "sha256-hUboFthw9ABwK6MRSNg7+iu9YbiJALNdsw9Ub3v43n4=";
+  };
+
+  installPhase = ''
+    runHook preInstall
+    install -D move-mount $out/bin/move-mount
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Toy binary to illustrate adding a mount beneath an existing mount";
+    mainProgram = "move-mount";
+    homepage = "https://github.com/brauner/move-mount-beneath";
+    license = lib.licenses.mit0;
+    maintainers = with lib.maintainers; [ nikstur ];
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/mo/movim/package.nix b/nixpkgs/pkgs/by-name/mo/movim/package.nix
new file mode 100644
index 000000000000..600af837b107
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/mo/movim/package.nix
@@ -0,0 +1,43 @@
+{ lib
+, fetchFromGitHub
+, php
+, phpCfg ? null
+, withPgsql ? true # “strongly recommended” according to docs
+, withMysql ? false
+}:
+
+php.buildComposerProject (finalAttrs: {
+  pname = "movim";
+  version = "0.23";
+
+  src = fetchFromGitHub {
+    owner = "movim";
+    repo = "movim";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-9MBe2IRYxvUuCc5m7ajvIlBU7YVm4A3RABlOOIjpKoM=";
+  };
+
+  php = php.buildEnv ({
+    extensions = ({ all, enabled }:
+      enabled
+        ++ (with all; [ curl dom gd imagick mbstring pdo simplexml ])
+        ++ lib.optionals withPgsql (with all; [ pdo_pgsql pgsql ])
+        ++ lib.optionals withMysql (with all; [ mysqli mysqlnd pdo_mysql ])
+    );
+  } // lib.optionalAttrs (phpCfg != null) {
+    extraConfig = phpCfg;
+  });
+
+  # no listed license
+  # pinned commonmark
+  composerStrictValidation = false;
+
+  vendorHash = "sha256-PBoJbVuF0Qy7nNlL4yx446ivlZpPYNIai78yC0wWkCM=";
+
+  meta = {
+    description = "a federated blogging & chat platform that acts as a web front end for the XMPP protocol";
+    homepage = "https://movim.eu";
+    license = lib.licenses.agpl3Plus;
+    maintainers = with lib.maintainers; [ toastal ];
+  };
+})