1 files changed, 50 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/by-name/ka/katriawm/package.nix b/nixpkgs/pkgs/by-name/ka/katriawm/package.nix
new file mode 100644
index 000000000000..85116255e24f
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/ka/katriawm/package.nix
@@ -0,0 +1,50 @@
+{ lib
+, stdenv
+, fetchzip
+, libX11
+, libXft
+, libXrandr
+, pkg-config
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "katriawm";
+  version = "23.08";
+
+  src = fetchzip {
+    url = "https://www.uninformativ.de/git/katriawm/archives/katriawm-v${finalAttrs.version}.tar.gz";
+    hash = "sha256-IWviLboZz421/Amz/QG4o8jYaG8Y/l5PvmvXfK5nzJE=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+  ];
+
+  buildInputs = [
+    libX11
+    libXft
+    libXrandr
+  ];
+
+  outputs = [ "out" "man" ];
+
+  strictDeps = true;
+
+  makeFlags = [ "-C" "src" ];
+
+  installFlags = [ "prefix=$(out)" ];
+
+  postPatch = ''
+    substituteInPlace src/config.mk \
+      --replace pkg-config "$PKG_CONFIG"
+  '';
+
+  meta = {
+    homepage = "https://www.uninformativ.de/git/katriawm/file/README.html";
+    description = "A non-reparenting, dynamic window manager with decorations";
+    license = lib.licenses.mit;
+    mainProgram = "katriawm";
+    maintainers = [ lib.maintainers.AndersonTorres ];
+    inherit (libX11.meta) platforms;
+  };
+})