5 files changed, 253 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/by-name/du/dublin-traceroute/package.nix b/nixpkgs/pkgs/by-name/du/dublin-traceroute/package.nix
new file mode 100644
index 000000000000..5f559c4d97c4
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/du/dublin-traceroute/package.nix
@@ -0,0 +1,41 @@
+{ lib, stdenv, fetchFromGitHub, cmake, pkg-config, jsoncpp, libtins, libpcap, openssl, unstableGitUpdater, nixosTests }:
+
+stdenv.mkDerivation {
+  pname = "dublin-traceroute";
+  version = "0.4.2-unstable-2024-01-09";
+
+  src = fetchFromGitHub {
+    owner = "insomniacslk";
+    repo = "dublin-traceroute";
+    rev = "b136db81cfbb30d5fd324dfccc97fca49a5ecee1";
+    hash = "sha256-FsolpeQGaLDjDE5Yk58t2hFQJgM58zafIx6s5ejYKnY=";
+  };
+
+  nativeBuildInputs = [ cmake pkg-config ];
+
+  buildInputs = [ jsoncpp libtins libpcap openssl ];
+
+  outputs = [
+    "out"
+    "lib"
+    "dev"
+  ];
+
+  passthru = {
+    # 0.4.2 was tagged in 2017
+    updateScript = unstableGitUpdater { };
+
+    tests = {
+      inherit (nixosTests) dublin-traceroute;
+    };
+  };
+
+  meta = with lib; {
+    description = "NAT-aware multipath traceroute tool";
+    homepage = "https://dublin-traceroute.net/";
+    license = licenses.bsd2;
+    maintainers = with maintainers; [ baloo ];
+    platforms = platforms.unix;
+    mainProgram = "dublin-traceroute";
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/du/dune3d/package.nix b/nixpkgs/pkgs/by-name/du/dune3d/package.nix
new file mode 100644
index 000000000000..797819354a1b
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/du/dune3d/package.nix
@@ -0,0 +1,65 @@
+{
+  cmake,
+  eigen,
+  fetchFromGitHub,
+  glm,
+  gobject-introspection,
+  gtkmm4,
+  lib,
+  libepoxy,
+  librsvg,
+  libspnav,
+  libuuid,
+  meson,
+  ninja,
+  opencascade-occt,
+  pkg-config,
+  python3,
+  stdenv,
+  wrapGAppsHook,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "dune3d";
+  version = "1.0.0";
+
+  src = fetchFromGitHub {
+    owner = "dune3d";
+    repo = "dune3d";
+    rev = "v${version}";
+    hash = "sha256-y7jlqH1p2vCFTM14rFURxTkrWUT5hNkCseC3xB6bFFo=";
+  };
+
+  nativeBuildInputs = [
+    gobject-introspection
+    meson
+    ninja
+    pkg-config
+    wrapGAppsHook
+  ];
+  buildInputs = [
+    cmake
+    eigen
+    glm
+    gtkmm4
+    libepoxy
+    librsvg
+    libspnav
+    libuuid
+    opencascade-occt
+    (python3.withPackages (pp: [
+      pp.pygobject3
+    ]))
+  ];
+
+  env.CASROOT = opencascade-occt;
+
+  meta = with lib; {
+    description = "3D CAD application";
+    homepage = "https://dune3d.org";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ _0x4A6F jue89 ];
+    mainProgram = "dune3d";
+    platforms = platforms.linux;
+  };
+}
diff --git a/nixpkgs/pkgs/by-name/du/dunst/package.nix b/nixpkgs/pkgs/by-name/du/dunst/package.nix
new file mode 100644
index 000000000000..f89bcd196ab3
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/du/dunst/package.nix
@@ -0,0 +1,62 @@
+{ stdenv, lib, fetchFromGitHub, makeWrapper
+, pkg-config, which, perl, jq, libXrandr, coreutils
+, cairo, dbus, systemd, gdk-pixbuf, glib, libX11, libXScrnSaver
+, wayland, wayland-protocols
+, libXinerama, libnotify, pango, xorgproto, librsvg
+, testers, dunst
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "dunst";
+  version = "1.10.0";
+
+  src = fetchFromGitHub {
+    owner = "dunst-project";
+    repo = "dunst";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-6smFUdWqOuYB0btsDgHtIpDBfHhkpIQfjyZ8wtRg1bQ=";
+  };
+
+  nativeBuildInputs = [ perl pkg-config which systemd makeWrapper ];
+
+  buildInputs = [
+    cairo dbus gdk-pixbuf glib libX11 libXScrnSaver
+    libXinerama libnotify pango xorgproto librsvg libXrandr
+    wayland wayland-protocols
+  ];
+
+  outputs = [ "out" "man" ];
+
+  makeFlags = [
+    "PREFIX=$(out)"
+    "VERSION=$(version)"
+    "SYSCONFDIR=$(out)/etc"
+    "SERVICEDIR_DBUS=$(out)/share/dbus-1/services"
+    "SERVICEDIR_SYSTEMD=$(out)/lib/systemd/user"
+  ];
+
+  postInstall = ''
+    wrapProgram $out/bin/dunst \
+      --set GDK_PIXBUF_MODULE_FILE "$GDK_PIXBUF_MODULE_FILE"
+
+    wrapProgram $out/bin/dunstctl \
+      --prefix PATH : "${lib.makeBinPath [ coreutils dbus ]}"
+
+    install -D contrib/_dunst.zshcomp $out/share/zsh/site-functions/_dunst
+    install -D contrib/_dunstctl.zshcomp $out/share/zsh/site-functions/_dunstctl
+    substituteInPlace $out/share/zsh/site-functions/_dunstctl \
+      --replace "jq -M" "${jq}/bin/jq -M"
+  '';
+
+  passthru.tests.version = testers.testVersion { package = dunst; };
+
+  meta = with lib; {
+    description = "Lightweight and customizable notification daemon";
+    homepage = "https://dunst-project.org/";
+    license = licenses.bsd3;
+    # NOTE: 'unix' or even 'all' COULD work too, I'm not sure
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ domenkozar ];
+    mainProgram = "dunst";
+  };
+})
diff --git a/nixpkgs/pkgs/by-name/du/durden/package.nix b/nixpkgs/pkgs/by-name/du/durden/package.nix
new file mode 100644
index 000000000000..3d72e132964a
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/du/durden/package.nix
@@ -0,0 +1,43 @@
+{ lib
+, stdenvNoCC
+, fetchFromGitHub
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "durden";
+  version = "unstable-2023-10-23";
+
+  src = fetchFromGitHub {
+    owner = "letoram";
+    repo = "durden";
+    rev = "347dba6da011bbaa70c6edaf82a2d915f4057db3";
+    hash = "sha256-iNf7fOzz7mf1CXG5leCenkSTrdCc9/KL8VLw8gUIyKE=";
+  };
+
+  dontConfigure = true;
+
+  dontBuild = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p ${placeholder "out"}/share/arcan/appl/
+    cp -a ./durden ${placeholder "out"}/share/arcan/appl/
+
+    runHook postInstall
+  '';
+
+  meta = {
+    homepage = "https://durden.arcan-fe.com/";
+    description = "Reference Desktop Environment for Arcan";
+    longDescription = ''
+      Durden is a desktop environment for the Arcan Display Server. It serves
+      both as a reference showcase on how to take advantage of some of the
+      features in Arcan, and as a very competent entry to the advanced-user side
+      of the desktop environment spectrum.
+    '';
+    license = with lib.licenses; [ bsd3 ];
+    maintainers = with lib.maintainers; [ AndersonTorres ];
+    platforms = lib.platforms.all;
+  };
+})
diff --git a/nixpkgs/pkgs/by-name/du/dust/package.nix b/nixpkgs/pkgs/by-name/du/dust/package.nix
new file mode 100644
index 000000000000..fff5b4c3dcc4
--- /dev/null
+++ b/nixpkgs/pkgs/by-name/du/dust/package.nix
@@ -0,0 +1,42 @@
+{ stdenv, lib, fetchFromGitHub, rustPlatform, AppKit, installShellFiles }:
+
+rustPlatform.buildRustPackage rec {
+  # Originally, this package was under the attribute `du-dust`, since `dust` was taken.
+  # Since then, `dust` has been freed up, allowing this package to take that attribute.
+  # However in order for tools like `nix-env` to detect package updates, keep `du-dust` for pname.
+  pname = "du-dust";
+  version = "0.9.0";
+
+  src = fetchFromGitHub {
+    owner = "bootandy";
+    repo = "dust";
+    rev = "v${version}";
+    hash = "sha256-5X7gRMTUrG6ecZnwExBTadOJo/HByohTMDsgxFmp1HM=";
+    # Remove unicode file names which leads to different checksums on HFS+
+    # vs. other filesystems because of unicode normalisation.
+    postFetch = ''
+      rm -r $out/tests/test_dir_unicode/
+    '';
+  };
+
+  cargoHash = "sha256-uc7jbA8HqsH1bSJgbnUVT/f7F7kZJ4Jf3yyFvseH7no=";
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  buildInputs = lib.optionals stdenv.isDarwin [ AppKit ];
+
+  doCheck = false;
+
+  postInstall = ''
+    installManPage man-page/dust.1
+    installShellCompletion completions/dust.{bash,fish} --zsh completions/_dust
+  '';
+
+  meta = with lib; {
+    description = "du + rust = dust. Like du but more intuitive";
+    homepage = "https://github.com/bootandy/dust";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ infinisil ];
+    mainProgram = "dust";
+  };
+}