1 files changed, 51 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/applications/networking/cluster/temporal/default.nix b/nixpkgs/pkgs/applications/networking/cluster/temporal/default.nix
new file mode 100644
index 000000000000..c6e5ba9df7a9
--- /dev/null
+++ b/nixpkgs/pkgs/applications/networking/cluster/temporal/default.nix
@@ -0,0 +1,51 @@
+{ lib, fetchFromGitHub, buildGoModule, testers, temporal }:
+
+buildGoModule rec {
+  pname = "temporal";
+  version = "1.22.6";
+
+  src = fetchFromGitHub {
+    owner = "temporalio";
+    repo = "temporal";
+    rev = "v${version}";
+    hash = "sha256-L5TOFhAMfbKjNK/Q74V2lcZs5vyynvMZMhHFB1ay5F8=";
+  };
+
+  vendorHash = "sha256-ItJ4Bng9TTGJpSHaNglODIheO2ZmntHl7QfK4+2I2CM=";
+
+  excludedPackages = [ "./build" ];
+
+  CGO_ENABLED = 0;
+
+  ldflags = [ "-s" "-w" ];
+
+  # There too many integration tests.
+  doCheck = false;
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/share
+    cp -r ./schema $out/share/
+
+    install -Dm755 "$GOPATH/bin/server" -T $out/bin/temporal-server
+    install -Dm755 "$GOPATH/bin/cassandra" -T $out/bin/temporal-cassandra-tool
+    install -Dm755 "$GOPATH/bin/sql" -T $out/bin/temporal-sql-tool
+    install -Dm755 "$GOPATH/bin/tdbg" -T $out/bin/tdbg
+
+    runHook postInstall
+  '';
+
+  passthru.tests.version = testers.testVersion {
+    package = temporal;
+  };
+
+  meta = with lib; {
+    description = "A microservice orchestration platform which enables developers to build scalable applications without sacrificing productivity or reliability";
+    homepage = "https://temporal.io";
+    changelog = "https://github.com/temporalio/temporal/releases/tag/v${version}";
+    license = licenses.mit;
+    maintainers = with maintainers; [ titanous ];
+    mainProgram = "temporal-server";
+  };
+}