1 files changed, 46 insertions, 0 deletions
diff --git a/nixpkgs/pkgs/applications/editors/sigil/default.nix b/nixpkgs/pkgs/applications/editors/sigil/default.nix
new file mode 100644
index 000000000000..adbbc05ccce5
--- /dev/null
+++ b/nixpkgs/pkgs/applications/editors/sigil/default.nix
@@ -0,0 +1,46 @@
+{ lib, mkDerivation, fetchFromGitHub, cmake, pkg-config, makeWrapper
+, boost, xercesc, hunspell, zlib, pcre16
+, qtbase, qttools, qtwebengine, qtxmlpatterns
+, python3Packages
+}:
+
+mkDerivation rec {
+  pname = "sigil";
+  version = "1.7.0";
+
+  src = fetchFromGitHub {
+    repo = "Sigil";
+    owner = "Sigil-Ebook";
+    rev = version;
+    sha256 = "sha256-a1gstR7qHbzQ3GZ0g/lxUxcHeZ5QgJIvhCV37tqlVfA=";
+  };
+
+  pythonPath = with python3Packages; [ lxml ];
+
+  nativeBuildInputs = [ cmake pkg-config makeWrapper ];
+
+  buildInputs = [
+    boost xercesc qtbase qttools qtwebengine qtxmlpatterns
+    python3Packages.lxml
+  ];
+
+  prePatch = ''
+    sed -i '/^QTLIB_DIR=/ d' src/Resource_Files/bash/sigil-sh_install
+  '';
+
+  dontWrapQtApps = true;
+
+  preFixup = ''
+    wrapProgram "$out/bin/sigil" \
+       --prefix PYTHONPATH : $PYTHONPATH \
+       ''${qtWrapperArgs[@]}
+  '';
+
+  meta = with lib; {
+    description = "Free, open source, multi-platform ebook (ePub) editor";
+    homepage = "https://github.com/Sigil-Ebook/Sigil/";
+    license = licenses.gpl3;
+    # currently unmaintained
+    platforms = platforms.linux;
+  };
+}