souffle: init at 1.0.0

2 files changed, 43 insertions, 0 deletions

diff --git a/pkgs/development/compilers/souffle/default.nix b/pkgs/development/compilers/souffle/default.nix
new file mode 100644
index 000000000000..68353e6a5d47
--- /dev/null
+++ b/pkgs/development/compilers/souffle/default.nix
@@ -0,0 +1,41 @@
+{ stdenv, fetchFromGitHub, autoconf, automake, boost, bison, flex, openjdk, doxygen, perl, graphviz }:
+
+stdenv.mkDerivation rec {
+  version = "1.0.0";
+  name    = "souffle-${version}";
+
+  src = fetchFromGitHub {
+    owner  = "souffle-lang";
+    repo   = "souffle";
+    rev    = version;
+    sha256 = "13j14227dgxcm25z9iizcav563wg2ak9338pb03aqqz8yqxbmz4n";
+  };
+
+  buildInputs = [
+    autoconf automake boost bison flex openjdk
+    # Used for docs
+    doxygen perl graphviz
+  ];
+
+  patchPhase = ''
+    substituteInPlace configure.ac \
+      --replace "m4_esyscmd([git describe --tags --abbrev=0 | tr -d '\n'])" "${version}"
+  '';
+
+  # Without this, we get an obscure error about not being able to find a library version
+  # without saying what library it's looking for. Turns out it's searching global paths
+  # for boost and failing there, so we tell it what's what here.
+  configureFlags = [ "--with-boost-libdir=${boost}/lib" ];
+
+  preConfigure = "./bootstrap";
+
+  enableParallelBuilding = true;
+
+  meta = with stdenv.lib; {
+    description = "A translator of declarative Datalog programs into the C++ language";
+    homepage    = "http://souffle-lang.github.io/";
+    platforms   = platforms.unix;
+    maintainers = with maintainers; [ copumpkin ];
+    license     = licenses.upl;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index ce7a23579eaf..acad02a206b9 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -5582,6 +5582,8 @@ in
 
   solc = callPackage ../development/compilers/solc { };
 
+  souffle = callPackage ../development/compilers/souffle { };
+
   sqldeveloper = callPackage ../development/tools/database/sqldeveloper { };
 
   squeak = callPackage ../development/compilers/squeak { };