networkmanager-vpnc: move to a subdirectory

1 files changed, 45 insertions, 0 deletions

diff --git a/pkgs/tools/networking/network-manager/vpnc/default.nix b/pkgs/tools/networking/network-manager/vpnc/default.nix
new file mode 100644
index 000000000000..577e04f6648d
--- /dev/null
+++ b/pkgs/tools/networking/network-manager/vpnc/default.nix
@@ -0,0 +1,45 @@
+{ stdenv, fetchurl, vpnc, intltool, pkgconfig, networkmanager, libsecret
+, withGnome ? true, gnome3, procps, kmod, file }:
+let
+  pname   = "NetworkManager-vpnc";
+  version = "1.2.6";
+in stdenv.mkDerivation rec {
+  name    = "${pname}${if withGnome then "-gnome" else ""}-${version}";
+
+  src = fetchurl {
+    url    = "mirror://gnome/sources/${pname}/${stdenv.lib.versions.majorMinor version}/${pname}-${version}.tar.xz";
+    sha256 = "1js5lwcsqws4klgypfxl4ikmakv7v7xgddij1fj6b0y0qicx0kyy";
+  };
+
+  buildInputs = [ vpnc networkmanager libsecret ]
+    ++ stdenv.lib.optionals withGnome [ gnome3.gtk gnome3.libgnome-keyring
+                                        gnome3.networkmanagerapplet ];
+
+  nativeBuildInputs = [ intltool pkgconfig file ];
+
+  configureFlags = [
+    "${if withGnome then "--with-gnome --with-gtkver=3" else "--without-gnome"}"
+    "--disable-static"
+  ];
+
+  preConfigure = ''
+     substituteInPlace "configure" \
+       --replace "/sbin/sysctl" "${procps}/bin/sysctl"
+     substituteInPlace "src/nm-vpnc-service.c" \
+       --replace "/sbin/vpnc" "${vpnc}/bin/vpnc" \
+       --replace "/sbin/modprobe" "${kmod}/bin/modprobe"
+  '';
+
+  passthru = {
+    updateScript = gnome3.updateScript {
+      packageName = pname;
+      attrPath = "networkmanager-vpnc";
+    };
+  };
+
+  meta = {
+    description = "NetworkManager's VPNC plugin";
+    inherit (networkmanager.meta) maintainers platforms;
+  };
+}
+