Python: move expressions in python-modules to their own folders

1 files changed, 49 insertions, 0 deletions

diff --git a/pkgs/development/python-modules/docker_compose/default.nix b/pkgs/development/python-modules/docker_compose/default.nix
new file mode 100644
index 000000000000..91a0c4183c9b
--- /dev/null
+++ b/pkgs/development/python-modules/docker_compose/default.nix
@@ -0,0 +1,49 @@
+{ stdenv, buildPythonApplication, fetchPypi, pythonOlder
+, mock, pytest, nose
+, pyyaml, backports_ssl_match_hostname, colorama, docopt
+, dockerpty, docker, ipaddress, jsonschema, requests
+, six, texttable, websocket_client, cached-property
+, enum34, functools32
+}:
+buildPythonApplication rec {
+  version = "1.15.0";
+  pname = "docker-compose";
+  name = "${pname}-${version}";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "0yg58m5kk22kihbra0h40miqnbdmkirjr9y47wns613sdikrymmg";
+  };
+
+  # lots of networking and other fails
+  doCheck = false;
+  buildInputs = [ mock pytest nose ];
+  propagatedBuildInputs = [
+    pyyaml backports_ssl_match_hostname colorama dockerpty docker
+    ipaddress jsonschema requests six texttable websocket_client
+    docopt cached-property
+  ] ++
+    stdenv.lib.optional (pythonOlder "3.4") enum34 ++
+    stdenv.lib.optional (pythonOlder "3.2") functools32;
+
+  patchPhase = ''
+    # Remove upper bound on requires, see also
+    # https://github.com/docker/compose/issues/4431
+    sed -i "s/, < .*',$/',/" setup.py
+  '';
+
+  postInstall = ''
+    mkdir -p $out/share/bash-completion/completions/
+    cp contrib/completion/bash/docker-compose $out/share/bash-completion/completions/docker-compose
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = https://docs.docker.com/compose/;
+    description = "Multi-container orchestration for Docker";
+    license = licenses.asl20;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [
+      jgeerds
+    ];
+  };
+}