Ruby: Separate 'install the current version of ruby' from 'install version x of ruby' when x is also the current version

svn path=/nixpkgs/trunk/; revision=29600

1 files changed, 52 insertions, 0 deletions

diff --git a/pkgs/development/interpreters/ruby/ruby-19.nix b/pkgs/development/interpreters/ruby/ruby-19.nix
new file mode 100644
index 000000000000..d5ccb19caecd
--- /dev/null
+++ b/pkgs/development/interpreters/ruby/ruby-19.nix
@@ -0,0 +1,52 @@
+{ stdenv, fetchurl
+, zlib, zlibSupport ? true
+, openssl, opensslSupport ? true
+, gdbm, gdbmSupport ? true
+, ncurses, readline, cursesSupport ? false
+, groff, docSupport ? false
+}:
+
+let
+  op = stdenv.lib.optional;
+  ops = stdenv.lib.optionals;
+in
+
+stdenv.mkDerivation rec {
+  version = with passthru; "${majorVersion}.${minorVersion}-p${patchLevel}";
+  
+  name = "ruby-${version}";
+  
+  src = fetchurl {
+    url = "ftp://ftp.ruby-lang.org/pub/ruby/1.9/${name}.tar.gz";
+    sha256 = "0zmxdqzprbdc5mvmba1i94mpqnqxxlh460jri7bx6i29bibigj0w";
+  };
+
+  # Have `configure' avoid `/usr/bin/nroff' in non-chroot builds.
+  NROFF = "${groff}/bin/nroff";
+
+  buildInputs = (ops cursesSupport [ ncurses readline ] )
+    ++ (op docSupport groff )
+    ++ (op zlibSupport zlib)
+    ++ (op opensslSupport openssl)
+    ++ (op gdbmSupport gdbm);
+    
+  configureFlags = ["--enable-shared" "--enable-pthread"];
+
+  installFlags = stdenv.lib.optionalString docSupport "install-doc";
+  # Bundler tries to create this directory
+  postInstall = "mkdir -pv $out/${passthru.gemPath}";
+
+  meta = {
+    license = "Ruby";
+    homepage = "http://www.ruby-lang.org/en/";
+    description = "The Ruby language";
+  };
+
+  passthru = rec {
+    majorVersion = "1.9";
+    minorVersion = "2";
+    patchLevel = "290";
+    libPath = "lib/ruby/${majorVersion}";
+    gemPath = "lib/ruby/gems/${majorVersion}";
+  };
+}