Merge master into staging-next

6 files changed, 209 insertions, 1 deletions

diff --git a/pkgs/desktops/deepin/deepin-desktop-schemas/default.nix b/pkgs/desktops/deepin/deepin-desktop-schemas/default.nix
new file mode 100644
index 000000000000..b1a9c52014b8
--- /dev/null
+++ b/pkgs/desktops/deepin/deepin-desktop-schemas/default.nix
@@ -0,0 +1,43 @@
+{ stdenv, fetchFromGitHub, python, deepin-gtk-theme,
+deepin-icon-theme, deepin-sound-theme, deepin-wallpapers, gnome3 }:
+
+stdenv.mkDerivation rec {
+  name = "${pname}-${version}";
+  pname = "deepin-desktop-schemas";
+  version = "3.2.18.7";
+
+  src = fetchFromGitHub {
+    owner = "linuxdeepin";
+    repo = pname;
+    rev = version;
+    sha256 = "1siv28wbfjydr3s9k9i5b9fin39yr8ys90f3wi7b8rfm3cr5yy6j";
+  };
+
+  nativeBuildInputs = [
+    python
+  ];
+
+  buildInputs = [
+    gnome3.dconf
+    deepin-gtk-theme
+    deepin-icon-theme
+    deepin-sound-theme
+    deepin-wallpapers
+  ];
+
+  postPatch = ''
+    # fix default background url
+    sed -i '/picture-uri/s|/usr/share/backgrounds/default_background.jpg|$out/share/backgrounds/deepin/default.png|' \
+      overrides/common/com.deepin.wrap.gnome.desktop.override
+  '';
+
+  makeFlags = [ "PREFIX=$(out)" ];
+
+  meta = with stdenv.lib; {
+    description = "GSettings deepin desktop-wide schemas";
+    homepage = https://github.com/linuxdeepin/deepin-desktop-schemas;
+    license = licenses.gpl3;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ romildo ];
+  };
+}
diff --git a/pkgs/desktops/deepin/deepin-metacity/default.nix b/pkgs/desktops/deepin/deepin-metacity/default.nix
new file mode 100644
index 000000000000..b5eb71108763
--- /dev/null
+++ b/pkgs/desktops/deepin/deepin-metacity/default.nix
@@ -0,0 +1,62 @@
+{ stdenv, fetchFromGitHub, pkgconfig, intltool, libtool, gnome3, bamf,
+  json-glib, libcanberra-gtk3, libxkbcommon, libstartup_notification,
+  deepin-wallpapers, deepin-desktop-schemas }:
+
+stdenv.mkDerivation rec {
+  name = "${pname}-${version}";
+  pname = "deepin-metacity";
+  version = "3.22.22";
+
+  src = fetchFromGitHub {
+    owner = "linuxdeepin";
+    repo = pname;
+    rev = version;
+    sha256 = "0gr10dv8vphla6z7zqiyyg3n3ag4rrlz43c4kr7fd5xwx2bfvp3d";
+  };
+
+  nativeBuildInputs = [
+    pkgconfig
+    intltool
+    libtool
+    gnome3.gnome-common
+    gnome3.glib.dev
+  ];
+
+  buildInputs = [
+    gnome3.dconf
+    gnome3.gtk
+    gnome3.libgtop
+    gnome3.zenity
+    bamf
+    json-glib
+    libcanberra-gtk3
+    libstartup_notification
+    libxkbcommon
+    deepin-wallpapers
+    deepin-desktop-schemas
+  ];
+
+  postPatch = ''
+    sed -i src/ui/deepin-background-cache.c \
+      -e 's;/usr/share/backgrounds/default_background.jpg;${deepin-wallpapers}/share/backgrounds/deepin/desktop.jpg;'
+  '';
+
+  NIX_CFLAGS_COMPILE = "-I${gnome3.glib.dev}/include/gio-unix-2.0";
+
+  configureFlags = [ "--disable-themes-documentation" ];
+
+  preConfigure = ''
+    HOME=$TMP
+    NOCONFIGURE=1 ./autogen.sh
+  '';
+
+  enableParallelBuilding = true;
+
+  meta = with stdenv.lib; {
+    description = "2D window manager for Deepin";
+    homepage = https://github.com/linuxdeepin/deepin-metacity;
+    license = licenses.gpl3;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ romildo ];
+  };
+}
diff --git a/pkgs/desktops/deepin/deepin-wallpapers/default.nix b/pkgs/desktops/deepin/deepin-wallpapers/default.nix
new file mode 100644
index 000000000000..ed2c795fd9cb
--- /dev/null
+++ b/pkgs/desktops/deepin/deepin-wallpapers/default.nix
@@ -0,0 +1,41 @@
+{ stdenv, fetchFromGitHub, dde-api }:
+
+stdenv.mkDerivation rec {
+  name = "deepin-wallpapers-${version}";
+  version = "1.7.5";
+
+  src = fetchFromGitHub {
+    owner = "linuxdeepin";
+    repo = "deepin-wallpapers";
+    rev = version;
+    sha256 = "0mfjkh81ci0gjwmgycrh32by7v9b73nyvyjbqd29ccpb8bpyyakn";
+  };
+
+  nativeBuildInputs = [ dde-api.bin ];
+
+  postPatch = ''
+    sed -i -e "s:/usr/lib/deepin-api:${dde-api.bin}/lib/deepin-api:" Makefile
+    sed -i -e "s:/usr/share/wallpapers:$out/share/wallpapers:" Makefile
+  '';
+
+  installPhase = ''
+    mkdir -p $out/share/wallpapers/deepin
+    cp -a deepin/* deepin-community/* deepin-private/* $out/share/wallpapers/deepin
+    mkdir -p $out/var/cache
+    cp -a image-blur $out/var/cache
+    
+    # Suggested by upstream
+    mkdir -p $out/share/backgrounds/deepin
+    ln -s ../../wallpapers/deepin/Hummingbird_by_Shu_Le.jpg $out/share/backgrounds/deepin/desktop.jpg
+    ln -s $(echo -n $out/share/wallpapers/deepin/Hummingbird_by_Shu_Le.jpg | md5sum | cut -d " " -f 1).jpg \
+      $out/var/cache/image-blur/$(echo -n $out/share/backgrounds/deepin/desktop.jpg | md5sum | cut -d " " -f 1).jpg
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Wallpapers for Deepin Desktop Environment";
+    homepage = https://github.com/linuxdeepin/deepin-wallpapers;
+    license = licenses.gpl3;
+    platforms = platforms.linux;
+    maintainers = [ maintainers.romildo ];
+  };
+}
diff --git a/pkgs/desktops/deepin/deepin-wm/default.nix b/pkgs/desktops/deepin/deepin-wm/default.nix
new file mode 100644
index 000000000000..f936934dcc0c
--- /dev/null
+++ b/pkgs/desktops/deepin/deepin-wm/default.nix
@@ -0,0 +1,58 @@
+{ stdenv, fetchFromGitHub, pkgconfig, intltool, libtool, vala, gnome3,
+  bamf, clutter-gtk, granite, libcanberra-gtk3, libwnck3,
+  deepin-mutter, deepin-wallpapers, deepin-desktop-schemas,
+  hicolor-icon-theme }:
+
+stdenv.mkDerivation rec {
+  name = "${pname}-${version}";
+  pname = "deepin-wm";
+  version = "1.9.32";
+
+  src = fetchFromGitHub {
+    owner = "linuxdeepin";
+    repo = pname;
+    rev = version;
+    sha256 = "02vwbkfpxcwv01vqa70pg7dm0lhm1lwhdqhk057r147a9cjb3ssc";
+  };
+
+  nativeBuildInputs = [
+    pkgconfig
+    intltool
+    libtool
+    gnome3.gnome-common
+    vala
+  ];
+
+  buildInputs = [
+    gnome3.gnome-desktop
+    gnome3.libgee
+    bamf
+    clutter-gtk
+    granite
+    libcanberra-gtk3
+    libwnck3
+    deepin-mutter
+    deepin-wallpapers
+    deepin-desktop-schemas
+    hicolor-icon-theme
+  ];
+
+  postPatch = ''
+    sed -i src/Background/BackgroundSource.vala \
+      -e 's;/usr/share/backgrounds/default_background.jpg;${deepin-wallpapers}/share/backgrounds/deepin/desktop.jpg;'
+  '';
+
+  preConfigure = ''
+    ./autogen.sh
+  '';
+
+  enableParallelBuilding = true;
+
+  meta = with stdenv.lib; {
+    description = "Deepin Window Manager";
+    homepage = https://github.com/linuxdeepin/deepin-wm;
+    license = licenses.gpl3;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ romildo ];
+  };
+}
diff --git a/pkgs/desktops/deepin/default.nix b/pkgs/desktops/deepin/default.nix
index 1ef7177e94d4..291aa8c11be1 100644
--- a/pkgs/desktops/deepin/default.nix
+++ b/pkgs/desktops/deepin/default.nix
@@ -7,11 +7,13 @@ let
     dde-api = callPackage ./dde-api { };
     dde-calendar = callPackage ./dde-calendar { };
     dde-qt-dbus-factory = callPackage ./dde-qt-dbus-factory { };
+    deepin-desktop-schemas = callPackage ./deepin-desktop-schemas { };
     deepin-gettext-tools = callPackage ./deepin-gettext-tools { };
     deepin-gtk-theme = callPackage ./deepin-gtk-theme { };
     deepin-icon-theme = callPackage ./deepin-icon-theme { };
     deepin-image-viewer = callPackage ./deepin-image-viewer { };
     deepin-menu = callPackage ./deepin-menu { };
+    deepin-metacity = callPackage ./deepin-metacity { };
     deepin-mutter = callPackage ./deepin-mutter { };
     deepin-shortcut-viewer = callPackage ./deepin-shortcut-viewer { };
     deepin-sound-theme = callPackage ./deepin-sound-theme { };
@@ -19,6 +21,8 @@ let
       inherit (pkgs.gnome3) libgee vte;
       wnck = pkgs.libwnck3;
     };
+    deepin-wallpapers = callPackage ./deepin-wallpapers { };
+    deepin-wm = callPackage ./deepin-wm { };
     dtkcore = callPackage ./dtkcore { };
     dtkwm = callPackage ./dtkwm { };
     dtkwidget = callPackage ./dtkwidget { };
diff --git a/pkgs/desktops/gnome-2/platform/GConf/default.nix b/pkgs/desktops/gnome-2/platform/GConf/default.nix
index dd9264514d4a..df3de11e738d 100644
--- a/pkgs/desktops/gnome-2/platform/GConf/default.nix
+++ b/pkgs/desktops/gnome-2/platform/GConf/default.nix
@@ -27,6 +27,6 @@ stdenv.mkDerivation rec {
   meta = with stdenv.lib; {
     homepage = https://projects.gnome.org/gconf/;
     description = "Deprecated system for storing application preferences";
-    platforms = platforms.linux;
+    platforms = platforms.unix;
   };
 }