* Rename xfce-4 to xfce-4.6 in preparation for Xfce 4.8.

svn path=/nixpkgs/trunk/; revision=28757

20 files changed, 495 insertions, 0 deletions

diff --git a/pkgs/desktops/xfce-4.6/applications/mousepad.nix b/pkgs/desktops/xfce-4.6/applications/mousepad.nix
new file mode 100644
index 000000000000..920151282a80
--- /dev/null
+++ b/pkgs/desktops/xfce-4.6/applications/mousepad.nix
@@ -0,0 +1,18 @@
+{ stdenv, fetchurl, pkgconfig, intltool, libxfce4util, libxfcegui4, gtk }:
+
+stdenv.mkDerivation rec {
+  name = "mousepad-0.2.16";
+  
+  src = fetchurl {
+    url = "http://www.xfce.org/archive/src/apps/mousepad/0.2/${name}.tar.bz2";
+    sha1 = "4e63033e0a71578f3ec9a0d2e6a505efd0424ef9";
+  };
+
+  buildInputs = [ pkgconfig intltool libxfce4util libxfcegui4 gtk ];
+
+  meta = {
+    homepage = http://www.xfce.org/projects/mousepad/;
+    description = "A simple text editor for Xfce";
+    license = "GPLv2+";
+  };
+}
diff --git a/pkgs/desktops/xfce-4.6/applications/ristretto.nix b/pkgs/desktops/xfce-4.6/applications/ristretto.nix
new file mode 100644
index 000000000000..198421e21d3f
--- /dev/null
+++ b/pkgs/desktops/xfce-4.6/applications/ristretto.nix
@@ -0,0 +1,24 @@
+{ stdenv, fetchurl, pkgconfig, intltool, libexif, gtk, thunar
+, exo, dbus_glib, libxfce4util, libxfcegui4, xfconf }:
+
+stdenv.mkDerivation rec {
+  name = "ristretto-0.0.22";
+  
+  src = fetchurl {
+    url = "http://www.xfce.org/archive/src/apps/ristretto/0.0/${name}.tar.gz";
+    sha1 = "bddbc8618ba67699ccf5ee4ea0b538b1be7fdb0a";
+  };
+
+  buildInputs =
+    [ pkgconfig intltool libexif gtk thunar exo dbus_glib
+      libxfce4util libxfcegui4 xfconf
+    ];
+
+  NIX_LDFLAGS = "-lX11";
+
+  meta = {
+    homepage = http://goodies.xfce.org/projects/applications/ristretto;
+    description = "A fast and lightweight picture-viewer for the Xfce desktop environment";
+    license = "GPLv2+";
+  };
+}
diff --git a/pkgs/desktops/xfce-4.6/applications/terminal.nix b/pkgs/desktops/xfce-4.6/applications/terminal.nix
new file mode 100644
index 000000000000..bd198a12af44
--- /dev/null
+++ b/pkgs/desktops/xfce-4.6/applications/terminal.nix
@@ -0,0 +1,23 @@
+{ stdenv, fetchurl
+, pkgconfig, ncurses
+, intltool, vte
+, exo, libxfce4util
+, gtk
+}:
+
+stdenv.mkDerivation {
+  name = "xfce-terminal-0.4.5";
+  
+  src = fetchurl {
+    url = http://archive.xfce.org/src/apps/terminal/0.4/Terminal-0.4.5.tar.bz2;
+    sha256 = "14w8mhmyrq6dd9574zfvq0pymknljckq6qgcv1r6c1r22jydrzcj";
+  };
+
+  buildInputs = [ pkgconfig intltool exo gtk vte libxfce4util ncurses ];
+
+  meta = {
+    homepage = http://www.xfce.org/projects/terminal;
+    description = "A modern terminal emulator primarily for the Xfce desktop environment";
+    license = "GPLv2+";
+  };
+}
diff --git a/pkgs/desktops/xfce-4.6/applications/xfce4-mixer.nix b/pkgs/desktops/xfce-4.6/applications/xfce4-mixer.nix
new file mode 100644
index 000000000000..db28274be072
--- /dev/null
+++ b/pkgs/desktops/xfce-4.6/applications/xfce4-mixer.nix
@@ -0,0 +1,38 @@
+{ stdenv, fetchurl, pkgconfig, intltool, glib, gst_all, gtk
+, libxfce4util, libxfcegui4, xfce4panel, xfconf, makeWrapper }:
+
+let
+
+  # The usual Gstreamer plugins package has a zillion dependencies
+  # that we don't need for a simple mixer, so build a minimal package.
+  gstPluginsBase = gst_all.gstPluginsBase.override {
+    minimalDeps = true;
+  };
+
+in
+
+stdenv.mkDerivation rec {
+  name = "xfce4-mixer-4.6.1";
+  
+  src = fetchurl {
+    url = "http://archive.xfce.org/src/apps/xfce4-mixer/4.6/${name}.tar.bz2";
+    sha1 = "e86163782fc4fc31671c7cb212d23d34106ad3af";
+  };
+
+  buildInputs =
+    [ pkgconfig intltool glib gst_all.gstreamer gstPluginsBase gtk
+      libxfce4util libxfcegui4 xfce4panel xfconf makeWrapper
+    ];
+
+  postInstall =
+    ''
+      mkdir -p $out/nix-support
+      echo ${gstPluginsBase} > $out/nix-support/propagated-user-env-packages
+    '';
+
+  meta = {
+    homepage = http://www.xfce.org/projects/xfce4-mixer;
+    description = "A volume control application for the Xfce desktop environment";
+    license = "GPLv2+";
+  };
+}
diff --git a/pkgs/desktops/xfce-4.6/applications/xfce4-power-manager.nix b/pkgs/desktops/xfce-4.6/applications/xfce4-power-manager.nix
new file mode 100644
index 000000000000..543b7660975f
--- /dev/null
+++ b/pkgs/desktops/xfce-4.6/applications/xfce4-power-manager.nix
@@ -0,0 +1,24 @@
+{ stdenv, fetchurl, pkgconfig, intltool, gtk, dbus_glib, xfconf
+, libxfcegui4, libxfce4util, libnotify, xfce4panel }:
+
+stdenv.mkDerivation rec {
+  name = "xfce4-power-manager-0.8.5";
+  
+  src = fetchurl {
+    url = "http://www.xfce.org/archive/src/apps/xfce4-power-manager/0.8/${name}.tar.bz2";
+    sha1 = "b1ce0f120733ec1a6267d50ba5c2990bbbbccfd4";
+  };
+
+  buildInputs =
+    [ pkgconfig intltool gtk dbus_glib xfconf libxfcegui4 libxfce4util
+      libnotify xfce4panel
+    ];
+
+  NIX_CFLAGS_COMPILE = "-I${libxfcegui4}/include/xfce4";
+
+  meta = {
+    homepage = http://goodies.xfce.org/projects/applications/xfce4-power-manager;
+    description = "A power manager for the Xfce Desktop Environment";
+    license = "GPLv2+";
+  };
+}
diff --git a/pkgs/desktops/xfce-4.6/art/xfce4-icon-theme.nix b/pkgs/desktops/xfce-4.6/art/xfce4-icon-theme.nix
new file mode 100644
index 000000000000..a17267a336c3
--- /dev/null
+++ b/pkgs/desktops/xfce-4.6/art/xfce4-icon-theme.nix
@@ -0,0 +1,17 @@
+{ stdenv, fetchurl, pkgconfig, intltool, gtk }:
+
+stdenv.mkDerivation rec {
+  name = "xfce4-icon-theme-4.4.3";
+  
+  src = fetchurl {
+    url = "http://www.xfce.org/archive/src/art/xfce4-icon-theme/4.4/${name}.tar.bz2";
+    sha1 = "0c0d0c45cd4a7f609310db8e9d17c1c4a131a6e7";
+  };
+
+  buildInputs = [ pkgconfig intltool gtk ];
+
+  meta = {
+    homepage = http://www.xfce.org/;
+    description = "Icons for Xfce";
+  };
+}
diff --git a/pkgs/desktops/xfce-4.6/core/exo.nix b/pkgs/desktops/xfce-4.6/core/exo.nix
new file mode 100644
index 000000000000..53fc8fa8fcdf
--- /dev/null
+++ b/pkgs/desktops/xfce-4.6/core/exo.nix
@@ -0,0 +1,21 @@
+{ stdenv, fetchurl, pkgconfig, intltool, URI, glib, gtk, libxfce4util
+, enableHAL ? true, hal, dbus_glib }:
+
+stdenv.mkDerivation rec {
+  name = "exo-0.3.107";
+  
+  src = fetchurl {
+    url = "http://www.xfce.org/archive/xfce/4.6.2/src/${name}.tar.bz2";
+    sha256 = "18z2xmdl577r60ln2waai10dd7i384k0bxrmf7gchrxd9c9aq4ha";
+  };
+
+  buildInputs =
+    [ pkgconfig intltool URI glib gtk libxfce4util ] ++
+    stdenv.lib.optionals enableHAL [ hal dbus_glib ];
+
+  meta = {
+    homepage = http://www.xfce.org/projects/exo;
+    description = "Application library for the Xfce desktop environment";
+    license = "GPLv2+";
+  };
+}
diff --git a/pkgs/desktops/xfce-4.6/core/gtk-xfce-engine.nix b/pkgs/desktops/xfce-4.6/core/gtk-xfce-engine.nix
new file mode 100644
index 000000000000..bab382a263f0
--- /dev/null
+++ b/pkgs/desktops/xfce-4.6/core/gtk-xfce-engine.nix
@@ -0,0 +1,19 @@
+{ stdenv, fetchurl, pkgconfig, intltool, gtk }:
+
+stdenv.mkDerivation rec {
+  name = "gtk-xfce-engine-2.6.0";
+  
+  src = fetchurl {
+    url = "http://www.xfce.org/archive/xfce/4.6.2/src/${name}.tar.bz2";
+    sha1 = "a7be2f330833d150c5fb37f68a4c2138348b5446";
+  };
+
+  buildInputs =
+    [ pkgconfig intltool gtk ];
+
+  meta = {
+    homepage = http://www.xfce.org/;
+    description = "GTK+ theme engine for Xfce";
+    license = "GPLv2+";
+  };
+}
diff --git a/pkgs/desktops/xfce-4.6/core/libxfce4menu.nix b/pkgs/desktops/xfce-4.6/core/libxfce4menu.nix
new file mode 100644
index 000000000000..f8a0c1ba87c9
--- /dev/null
+++ b/pkgs/desktops/xfce-4.6/core/libxfce4menu.nix
@@ -0,0 +1,18 @@
+{ stdenv, fetchurl, pkgconfig, glib, intltool, gtk, libxfce4util }:
+
+stdenv.mkDerivation rec {
+  name = "libxfce4menu-4.6.2";
+  
+  src = fetchurl {
+    url = "http://www.xfce.org/archive/xfce-4.6.2/src/${name}.tar.bz2";
+    sha1 = "32a85c1ad31360347d5a2f240c4ddc08b444d124";
+  };
+
+  buildInputs = [ pkgconfig glib intltool gtk libxfce4util ];
+
+  meta = {
+    homepage = http://www.xfce.org/;
+    description = "Xfce menu support library";
+    license = "LGPLv2+";
+  };
+}
diff --git a/pkgs/desktops/xfce-4.6/core/libxfce4util.nix b/pkgs/desktops/xfce-4.6/core/libxfce4util.nix
new file mode 100644
index 000000000000..2625966bb587
--- /dev/null
+++ b/pkgs/desktops/xfce-4.6/core/libxfce4util.nix
@@ -0,0 +1,18 @@
+{ stdenv, fetchurl, pkgconfig, glib, intltool }:
+
+stdenv.mkDerivation rec {
+  name = "libxfce4util-4.6.2";
+  
+  src = fetchurl {
+    url = "http://www.xfce.org/archive/xfce-4.6.2/src/${name}.tar.bz2";
+    sha256 = "10wcw7r8cjb0farffic037pcjr5bwrjrm8s3jrcb7c0b038pwbmf";
+  };
+
+  buildInputs = [ pkgconfig glib intltool ];
+
+  meta = {
+    homepage = http://www.xfce.org/;
+    description = "Basic utility non-GUI functions for Xfce";
+    license = "bsd";
+  };
+}
diff --git a/pkgs/desktops/xfce-4.6/core/libxfcegui4.nix b/pkgs/desktops/xfce-4.6/core/libxfcegui4.nix
new file mode 100644
index 000000000000..52ee3a6262fc
--- /dev/null
+++ b/pkgs/desktops/xfce-4.6/core/libxfcegui4.nix
@@ -0,0 +1,29 @@
+{ stdenv, fetchurl, pkgconfig, intltool, gtk, libxfce4util, xfconf
+, libglade, libstartup_notification }:
+
+stdenv.mkDerivation rec {
+  name = "libxfcegui4-4.6.4";
+  
+  src = fetchurl {
+    url = "http://www.xfce.org/archive/xfce-4.6.2/src/${name}.tar.bz2";
+    sha1 = "a12c79f8fa14c5d1fc0fca5615a451b7d23f8695";
+  };
+
+  # By default, libxfcegui4 tries to install into libglade's prefix.
+  # Install into our own prefix instead.
+  preConfigure =
+    ''
+      configureFlags="--with-libglade-module-path=$out/lib/libglade/2.0"
+    '';
+
+  buildInputs =
+    [ pkgconfig intltool gtk libxfce4util xfconf libglade
+      libstartup_notification
+    ];
+
+  meta = {
+    homepage = http://www.xfce.org/;
+    description = "Basic GUI library for Xfce";
+    license = "LGPLv2+";
+  };
+}
diff --git a/pkgs/desktops/xfce-4.6/core/thunar.nix b/pkgs/desktops/xfce-4.6/core/thunar.nix
new file mode 100644
index 000000000000..adbbd461c5ee
--- /dev/null
+++ b/pkgs/desktops/xfce-4.6/core/thunar.nix
@@ -0,0 +1,25 @@
+{ stdenv, fetchurl, pkgconfig, intltool, exo, gtk, libxfce4util
+, dbus_glib, libstartup_notification, xfconf, hal, xfce4panel
+, gamin }:
+
+stdenv.mkDerivation rec {
+  name = "thunar-1.0.2";
+  
+  src = fetchurl {
+    url = http://www.xfce.org/archive/xfce/4.6.2/src/Thunar-1.0.2.tar.bz2;
+    sha1 = "f7ae00c32402e4bc502aba15477b78e2c558c7c3";
+  };
+
+  buildInputs =
+    [ pkgconfig intltool exo gtk libxfce4util
+      dbus_glib libstartup_notification xfconf xfce4panel gamin
+    ];
+
+  propagatedBuildInputs = [ hal ];
+
+  meta = {
+    homepage = http://thunar.xfce.org/;
+    description = "Xfce file manager";
+    license = "GPLv2+";
+  };
+}
diff --git a/pkgs/desktops/xfce-4.6/core/xfce-utils.nix b/pkgs/desktops/xfce-4.6/core/xfce-utils.nix
new file mode 100644
index 000000000000..4f520058ccf1
--- /dev/null
+++ b/pkgs/desktops/xfce-4.6/core/xfce-utils.nix
@@ -0,0 +1,20 @@
+{ stdenv, fetchurl, pkgconfig, intltool, gtk, libxfce4util, libxfcegui4 }:
+
+stdenv.mkDerivation rec {
+  name = "xfce-utils-4.6.2";
+  
+  src = fetchurl {
+    url = "http://www.xfce.org/archive/xfce/4.6.2/src/${name}.tar.bz2";
+    sha1 = "6373886c3d70e576859741bde747a235567ffd8e";
+  };
+
+  configureFlags = "--with-xsession-prefix=$(out)/share/xsessions";
+
+  buildInputs = [ pkgconfig intltool gtk libxfce4util libxfcegui4 ];
+
+  meta = {
+    homepage = http://www.xfce.org/;
+    description = "Utilities and scripts for Xfce";
+    license = "GPLv2+";
+  };
+}
diff --git a/pkgs/desktops/xfce-4.6/core/xfce4-panel.nix b/pkgs/desktops/xfce-4.6/core/xfce4-panel.nix
new file mode 100644
index 000000000000..b8a8c1458011
--- /dev/null
+++ b/pkgs/desktops/xfce-4.6/core/xfce4-panel.nix
@@ -0,0 +1,24 @@
+{ stdenv, fetchurl, pkgconfig, intltool, gtk, libxfce4util, libxfcegui4
+, libwnck, exo, libstartup_notification }:
+
+stdenv.mkDerivation rec {
+  name = "xfce4-panel-4.6.4";
+  
+  src = fetchurl {
+    url = "http://www.xfce.org/archive/xfce/4.6.2/src/${name}.tar.bz2";
+    sha1 = "d2b310c036be84ed9886c06ae35b7a1a8eabfcb8";
+  };
+
+  buildInputs =
+    [ pkgconfig intltool gtk libxfce4util exo libwnck
+      libstartup_notification
+    ];
+
+  propagatedBuildInputs = [ libxfcegui4 ];
+
+  meta = {
+    homepage = http://www.xfce.org/;
+    description = "Xfce panel";
+    license = "GPLv2+";
+  };
+}
diff --git a/pkgs/desktops/xfce-4.6/core/xfce4-session.nix b/pkgs/desktops/xfce-4.6/core/xfce4-session.nix
new file mode 100644
index 000000000000..dc563502542a
--- /dev/null
+++ b/pkgs/desktops/xfce-4.6/core/xfce4-session.nix
@@ -0,0 +1,22 @@
+{ stdenv, fetchurl, pkgconfig, intltool, gtk, libxfce4util, libxfcegui4
+, libwnck, dbus_glib, xfconf, libglade, xorg }:
+
+stdenv.mkDerivation rec {
+  name = "xfce4-session-4.6.2";
+  
+  src = fetchurl {
+    url = "http://www.xfce.org/archive/xfce/4.6.2/src/${name}.tar.bz2";
+    sha1 = "2a5778a1543f97845f118a186e2dbb8a8ea3ff4b";
+  };
+
+  buildInputs =
+    [ pkgconfig intltool gtk libxfce4util libxfcegui4 libwnck dbus_glib
+      xfconf libglade xorg.iceauth
+    ];
+
+  meta = {
+    homepage = http://www.xfce.org/;
+    description = "Session manager for Xfce";
+    license = "GPLv2+";
+  };
+}
diff --git a/pkgs/desktops/xfce-4.6/core/xfce4-settings.nix b/pkgs/desktops/xfce-4.6/core/xfce4-settings.nix
new file mode 100644
index 000000000000..b0bfadf8e525
--- /dev/null
+++ b/pkgs/desktops/xfce-4.6/core/xfce4-settings.nix
@@ -0,0 +1,24 @@
+{ stdenv, fetchurl, pkgconfig, intltool, exo, gtk, libxfce4util, libxfcegui4
+, libglade, xfconf, xorg, libwnck, libnotify }:
+
+stdenv.mkDerivation rec {
+  name = "xfce4-settings-4.6.5";
+  
+  src = fetchurl {
+    url = "http://www.xfce.org/archive/xfce/4.6.2/src/${name}.tar.bz2";
+    sha1 = "c036cc2f3100a46b2649e678dff7c0106b219263";
+  };
+
+  buildInputs =
+    [ pkgconfig intltool exo gtk libxfce4util libxfcegui4 libglade
+      xfconf xorg.libXi xorg.libXcursor libwnck libnotify
+    #gtk libxfce4util libxfcegui4 libwnck dbus_glib
+      #xfconf libglade xorg.iceauth
+    ];
+
+  meta = {
+    homepage = http://www.xfce.org/;
+    description = "Settings manager for Xfce";
+    license = "GPLv2+";
+  };
+}
diff --git a/pkgs/desktops/xfce-4.6/core/xfconf.nix b/pkgs/desktops/xfce-4.6/core/xfconf.nix
new file mode 100644
index 000000000000..b4c14ef043e2
--- /dev/null
+++ b/pkgs/desktops/xfce-4.6/core/xfconf.nix
@@ -0,0 +1,20 @@
+{ stdenv, fetchurl, pkgconfig, intltool, glib, libxfce4util, dbus_glib }:
+
+stdenv.mkDerivation rec {
+  name = "xfconf-4.6.2";
+  
+  src = fetchurl {
+    url = "http://www.xfce.org/archive/xfce/4.6.2/src/${name}.tar.bz2";
+    sha1 = "2b9656a1b7f323d2600ddc929191afb50c8018f8";
+  };
+
+  buildInputs = [ pkgconfig intltool glib libxfce4util ];
+
+  propagatedBuildInputs = [ dbus_glib ];
+
+  meta = {
+    homepage = http://www.xfce.org/;
+    description = "Simple client-server configuration storage and query system for Xfce";
+    license = "GPLv2";
+  };
+}
diff --git a/pkgs/desktops/xfce-4.6/core/xfdesktop.nix b/pkgs/desktops/xfce-4.6/core/xfdesktop.nix
new file mode 100644
index 000000000000..83de4ed4dfe7
--- /dev/null
+++ b/pkgs/desktops/xfce-4.6/core/xfdesktop.nix
@@ -0,0 +1,22 @@
+{ stdenv, fetchurl, pkgconfig, intltool, gtk, libxfce4util, libxfcegui4
+, libwnck, xfconf, libglade, libxfce4menu, xfce4panel, thunar, exo }:
+
+stdenv.mkDerivation rec {
+  name = "xfdesktop-4.6.2";
+  
+  src = fetchurl {
+    url = "http://www.xfce.org/archive/xfce/4.6.2/src/${name}.tar.bz2";
+    sha1 = "cefcd1c1386d34386d4e900cbf88b7c24ef3bafb";
+  };
+
+  buildInputs =
+    [ pkgconfig intltool gtk libxfce4util libxfcegui4 libwnck xfconf
+      libglade libxfce4menu xfce4panel thunar exo
+    ];
+
+  meta = {
+    homepage = http://www.xfce.org/;
+    description = "Xfce desktop manager";
+    license = "GPLv2+";
+  };
+}
diff --git a/pkgs/desktops/xfce-4.6/core/xfwm4.nix b/pkgs/desktops/xfce-4.6/core/xfwm4.nix
new file mode 100644
index 000000000000..c7bab240691e
--- /dev/null
+++ b/pkgs/desktops/xfce-4.6/core/xfwm4.nix
@@ -0,0 +1,23 @@
+{ stdenv, fetchurl, pkgconfig, gtk, intltool, libglade, libxfce4util
+, libxfcegui4, xfconf, libwnck, libstartup_notification, xorg }:
+
+stdenv.mkDerivation rec {
+  name = "xfwm4-4.6.2";
+  
+  src = fetchurl {
+    url = "http://www.xfce.org/archive/xfce/4.6.2/src/${name}.tar.bz2";
+    sha256 = "0a2q2pr5mzp6hsrd0llr90i9wii2qj2054shkpvkain20gp1ja11";
+  };
+
+  buildInputs =
+    [ pkgconfig intltool gtk libglade libxfce4util libxfcegui4 xfconf
+      libwnck libstartup_notification
+      xorg.libXcomposite xorg.libXfixes xorg.libXdamage
+    ];
+
+  meta = {
+    homepage = http://www.xfce.org/;
+    description = "Window manager for Xfce";
+    license = "GPLv2+";
+  };
+}
diff --git a/pkgs/desktops/xfce-4.6/default.nix b/pkgs/desktops/xfce-4.6/default.nix
new file mode 100644
index 000000000000..6f2eaf1b4bfe
--- /dev/null
+++ b/pkgs/desktops/xfce-4.6/default.nix
@@ -0,0 +1,66 @@
+{ callPackage, pkgs }:
+
+rec {
+  inherit (pkgs.gtkLibs) gtk glib;
+
+  #### CORE
+
+  exo = callPackage ./core/exo.nix {
+    inherit (pkgs.perlPackages) URI;
+  };
+
+  libxfce4util = callPackage ./core/libxfce4util.nix { };
+
+  libxfcegui4 = callPackage ./core/libxfcegui4.nix {
+    inherit (pkgs.gnome) libglade;
+  };
+
+  libxfce4menu = callPackage ./core/libxfce4menu.nix { };
+
+  xfconf = callPackage ./core/xfconf.nix { };
+
+  xfwm4 = callPackage ./core/xfwm4.nix {
+    inherit (pkgs.gnome) libglade libwnck;
+  };
+
+  xfceutils = callPackage ./core/xfce-utils.nix { };
+
+  xfce4session = callPackage ./core/xfce4-session.nix {
+    inherit (pkgs.gnome) libglade libwnck;
+  };
+
+  xfce4settings = callPackage ./core/xfce4-settings.nix {
+    inherit (pkgs.gnome) libglade libwnck;
+  };
+
+  xfce4panel = callPackage ./core/xfce4-panel.nix {
+    inherit (pkgs.gnome) libwnck;
+  };
+
+  xfdesktop = callPackage ./core/xfdesktop.nix {
+    inherit (pkgs.gnome) libwnck libglade;
+  };
+
+  thunar = callPackage ./core/thunar.nix { };
+
+  gtk_xfce_engine = callPackage ./core/gtk-xfce-engine.nix { };
+
+  #### APPLICATIONS
+  
+  terminal = callPackage ./applications/terminal.nix {
+    inherit (pkgs.gnome) vte;
+  };
+
+  mousepad = callPackage ./applications/mousepad.nix { };
+
+  ristretto = callPackage ./applications/ristretto.nix { };
+
+  xfce4_power_manager = callPackage ./applications/xfce4-power-manager.nix { };
+
+  xfce4mixer = callPackage ./applications/xfce4-mixer.nix { };
+
+  #### ART
+
+  xfce4icontheme = callPackage ./art/xfce4-icon-theme.nix { };
+  
+}