Merge remote-tracking branch 'upstream/master' into hardened-stdenv

3 files changed, 125 insertions, 0 deletions

diff --git a/pkgs/applications/video/openshot-qt/default.nix b/pkgs/applications/video/openshot-qt/default.nix
new file mode 100644
index 000000000000..5f142d715f58
--- /dev/null
+++ b/pkgs/applications/video/openshot-qt/default.nix
@@ -0,0 +1,48 @@
+{stdenv, fetchurl, fetchFromGitHub, callPackage, makeWrapper, doxygen
+, ffmpeg, python3Packages, qt55}:
+
+with stdenv.lib;
+
+let
+  libopenshot = callPackage ./libopenshot.nix {};
+in
+stdenv.mkDerivation rec {
+  name = "openshot-qt-${version}";
+  version = "2.0.7";
+
+  src = fetchFromGitHub {
+    owner = "OpenShot";
+    repo = "openshot-qt";
+    rev = "v${version}";
+    sha256 = "1s4b61fd8cyjy8kvc25mqd97dkxx6gqmz02i42rrcriz51pw8wgh";
+  };
+
+  buildInputs = [doxygen python3Packages.python makeWrapper ffmpeg];
+
+  propagatedBuildInputs = [
+    qt55.qtbase
+    qt55.qtmultimedia
+    libopenshot
+  ];
+
+  installPhase = ''
+    mkdir -p $(toPythonPath $out)
+    cp -r src/* $(toPythonPath $out)
+    mkdir -p $out/bin
+    echo "#/usr/bin/env sh" >$out/bin/openshot-qt
+    echo "exec ${python3Packages.python.interpreter} $(toPythonPath $out)/launch.py" >>$out/bin/openshot-qt
+    chmod +x $out/bin/openshot-qt
+    wrapProgram $out/bin/openshot-qt \
+      --prefix PYTHONPATH : "$(toPythonPath $out):$(toPythonPath ${libopenshot}):$(toPythonPath ${python3Packages.pyqt5}):$(toPythonPath ${python3Packages.sip_4_16}):$(toPythonPath ${python3Packages.httplib2}):$PYTHONPATH"
+  '';
+
+  doCheck = false;
+
+  meta = {
+    homepage = "http://openshot.org/";
+    description = "Free, open-source video editor";
+    license = licenses.gpl3Plus;
+    maintainers = [maintainers.tohl];
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/applications/video/openshot-qt/libopenshot-audio.nix b/pkgs/applications/video/openshot-qt/libopenshot-audio.nix
new file mode 100644
index 000000000000..8b583d4ec5cb
--- /dev/null
+++ b/pkgs/applications/video/openshot-qt/libopenshot-audio.nix
@@ -0,0 +1,31 @@
+{stdenv, fetchurl, fetchFromGitHub, cmake, doxygen
+, libX11, libXft, libXrandr, libXinerama, libXext, libXcursor, alsaLib}:
+
+with stdenv.lib;
+
+stdenv.mkDerivation rec {
+  name = "libopenshot-audio-${version}";
+  version = "0.1.1";
+
+  src = fetchFromGitHub {
+    owner = "OpenShot";
+    repo = "libopenshot-audio";
+    rev = "v${version}";
+    sha256 = "0pgw7vzx3znglwm58187ybhg5maa13n4xcy5hrhzfsp8bqhrwkc7";
+  };
+
+  buildInputs = [
+    cmake doxygen
+    libX11 libXft libXrandr libXinerama libXext libXcursor alsaLib
+  ];
+
+  doCheck = false;
+
+  meta = {
+    homepage = "http://openshot.org/";
+    description = "Free, open-source video editor";
+    license = licenses.gpl3Plus;
+    maintainers = [maintainers.tohl];
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/applications/video/openshot-qt/libopenshot.nix b/pkgs/applications/video/openshot-qt/libopenshot.nix
new file mode 100644
index 000000000000..2737c48ec83d
--- /dev/null
+++ b/pkgs/applications/video/openshot-qt/libopenshot.nix
@@ -0,0 +1,46 @@
+{stdenv, fetchurl, fetchFromGitHub, callPackage, cmake, doxygen
+, imagemagick, ffmpeg, qt55, swig, python3, ruby, unittest-cpp}:
+
+with stdenv.lib;
+
+let
+  libopenshot_audio = callPackage ./libopenshot-audio.nix {};
+in
+stdenv.mkDerivation rec {
+  name = "libopenshot-${version}";
+  version = "0.1.1";
+
+  src = fetchFromGitHub {
+    owner = "OpenShot";
+    repo = "libopenshot";
+    rev = "v${version}";
+    sha256 = "12nfkris7spn8n4s8fvy2f6yk1hqh97wzh1z3fsdxldg4gppi903";
+  };
+
+  patchPhase = ''
+    sed -i 's/{UNITTEST++_INCLUDE_DIR}/ENV{UNITTEST++_INCLUDE_DIR}/g' tests/CMakeLists.txt
+    sed -i 's/{_REL_PYTHON_MODULE_PATH}/ENV{_REL_PYTHON_MODULE_PATH}/g' src/bindings/python/CMakeLists.txt
+    sed -i 's/{RUBY_VENDOR_ARCH_DIR}/ENV{RUBY_VENDOR_ARCH_DIR}/g' src/bindings/ruby/CMakeLists.txt
+    export _REL_PYTHON_MODULE_PATH=$(toPythonPath $out)
+    export RUBY_VENDOR_ARCH_DIR=$out/lib/ruby/site-packages
+  '';
+
+  buildInputs = [
+    cmake doxygen
+    imagemagick ffmpeg qt55.qtbase qt55.qtmultimedia swig python3 ruby
+    unittest-cpp
+  ];
+
+  LIBOPENSHOT_AUDIO_DIR = "${libopenshot_audio}";
+  "UNITTEST++_INCLUDE_DIR" = "${unittest-cpp}/include/UnitTest++";
+
+  doCheck = false;
+
+  meta = {
+    homepage = "http://openshot.org/";
+    description = "Free, open-source video editor";
+    license = licenses.gpl3Plus;
+    maintainers = [maintainers.tohl];
+    platforms = platforms.linux;
+  };
+}