deluge: 1.3.13 -> 1.3.15

Change libtorrentRasterbar dependency to 1.0.x series (required for
1.3.x series)
Move Deluge out of pythonPackages (it doesn't support Python 3)

1 files changed, 31 insertions, 0 deletions

diff --git a/pkgs/applications/networking/p2p/deluge/default.nix b/pkgs/applications/networking/p2p/deluge/default.nix
new file mode 100644
index 000000000000..7f8594b8bbb1
--- /dev/null
+++ b/pkgs/applications/networking/p2p/deluge/default.nix
@@ -0,0 +1,31 @@
+{ stdenv, fetchurl, intltool, libtorrentRasterbar_1_0, pythonPackages }:
+pythonPackages.buildPythonPackage rec {
+  name = "deluge-${version}";
+  version = "1.3.15";
+
+  src = fetchurl {
+    url = "http://download.deluge-torrent.org/source/${name}.tar.bz2";
+    sha256 = "1467b9hmgw59gf398mhbf40ggaka948yz3afh6022v753c9j7y6w";
+  };
+
+  propagatedBuildInputs = with pythonPackages; [
+    pyGtkGlade libtorrentRasterbar_1_0 twisted Mako chardet pyxdg pyopenssl service-identity
+  ];
+
+  nativeBuildInputs = [ intltool ];
+
+  postInstall = ''
+     mkdir -p $out/share/applications
+     cp -R deluge/data/pixmaps $out/share/
+     cp -R deluge/data/icons $out/share/
+     cp deluge/data/share/applications/deluge.desktop $out/share/applications
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = http://deluge-torrent.org;
+    description = "Torrent client";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ domenkozar ebzzry ];
+    platforms = platforms.all;
+  };
+}