Add libguestfs, tools for accessing and modifying virtual machine images

4 files changed, 85 insertions, 0 deletions

diff --git a/pkgs/development/libraries/libguestfs/default.nix b/pkgs/development/libraries/libguestfs/default.nix
new file mode 100644
index 000000000000..27e1c6adc008
--- /dev/null
+++ b/pkgs/development/libraries/libguestfs/default.nix
@@ -0,0 +1,55 @@
+{ stdenv, fetchurl, pkgconfig, autoconf, automake, libtool, makeWrapper
+, ncurses, cpio, gperf, perl, cdrkit, flex, bison, qemu, pcre, augeas, libxml2
+, acl, libcap, libcap_ng, libconfig, systemd, fuse, yajl, libvirt, hivex
+, gmp, readline, file, libintlperl, GetoptLong, SysVirt }:
+
+stdenv.mkDerivation rec {
+  name = "libguestfs-${version}";
+  version = "1.29.5";
+
+  appliance = fetchurl {
+    url = "http://libguestfs.org/download/binaries/appliance/appliance-1.26.0.tar.xz";
+    sha256 = "1kzvgmy845kclvr93y6rdpss2q0p8yfqg14r0i1pi5r4zc68yvj4";
+  };
+
+  src = fetchurl {
+    url = "http://libguestfs.org/download/1.29-development/libguestfs-${version}.tar.gz";
+    sha256 = "1il0p3irwcyfdm83935hj4bvxsx0kdfn8dvqmg2lbzap17jvzj8h";
+  };
+
+  buildInputs = [
+    makeWrapper pkgconfig autoconf automake libtool ncurses cpio gperf perl
+    cdrkit flex bison qemu pcre augeas libxml2 acl libcap libcap_ng libconfig
+    systemd fuse yajl libvirt gmp readline file hivex libintlperl GetoptLong
+    SysVirt
+  ];
+
+  configureFlags = "--disable-appliance --disable-daemon";
+  patches = [ ./libguestfs-syms.patch ];
+  NIX_CFLAGS_COMPILE="-I${libxml2}/include/libxml2/";
+
+  preConfigure = ''
+    AUTOPOINT=true LIBTOOLIZE=true autoreconf --verbose --install
+  '';
+
+  postInstall = ''
+    for bin in $out/bin/*; do
+      wrapProgram "$bin" \
+        --prefix "PATH" : "$out/bin:${hivex}/bin" \
+        --prefix "PERL5LIB" : "$PERL5LIB:$out/lib/perl5/site_perl"
+    done
+  '';
+
+  postFixup = ''
+    mkdir -p "$out/lib/guestfs"
+    tar -Jxvf "$appliance" --strip 1 -C "$out/lib/guestfs"
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Tools for accessing and modifying virtual machine disk images";
+    license = licenses.gpl2;
+    homepage = http://libguestfs.org/;
+    maintainers = with maintainers; [offline];
+    platforms = with platforms; linux;
+  };
+}
diff --git a/pkgs/development/libraries/libguestfs/libguestfs-syms.patch b/pkgs/development/libraries/libguestfs/libguestfs-syms.patch
new file mode 100644
index 000000000000..44cdc4e69b2e
--- /dev/null
+++ b/pkgs/development/libraries/libguestfs/libguestfs-syms.patch
@@ -0,0 +1,13 @@
+diff -rupN libguestfs-1.29.5/src/Makefile.am libguestfs-1.29.5-new/src/Makefile.am
+--- libguestfs-1.29.5/src/Makefile.am	2014-11-05 16:43:08.000000000 +0100
++++ libguestfs-1.29.5-new/src/Makefile.am	2014-11-05 20:07:45.760730596 +0100
+@@ -167,8 +167,7 @@ libguestfs_la_LIBADD = \
+ # Force libtool to name the library 'libguestfs.so.0.$(MAX_PROC_NR).0'.
+ # Include the version script to limit which symbols are exported.
+ libguestfs_la_LDFLAGS = \
+-	-version-info $(MAX_PROC_NR):0:$(MAX_PROC_NR) \
+-	$(VERSION_SCRIPT_FLAGS)$(srcdir)/libguestfs.syms
++	-version-info $(MAX_PROC_NR):0:$(MAX_PROC_NR)
+ 
+ if HAVE_FUSE
+ # XXX Unfortunately FUSE_CFLAGS defines _FILE_OFFSET_BITS=64.
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 20b7ed4dfdc5..2816ed82b9ee 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -5831,6 +5831,10 @@ let
 
   libgsystem = callPackage ../development/libraries/libgsystem { };
 
+  libguestfs = callPackage ../development/libraries/libguestfs {
+    inherit (perlPackages) libintlperl GetoptLong SysVirt;
+  };
+
   libharu = callPackage ../development/libraries/libharu { };
 
   libHX = callPackage ../development/libraries/libHX { };
diff --git a/pkgs/top-level/perl-packages.nix b/pkgs/top-level/perl-packages.nix
index 5fa7fddfabe6..8b0ee4cfa5b5 100644
--- a/pkgs/top-level/perl-packages.nix
+++ b/pkgs/top-level/perl-packages.nix
@@ -8305,6 +8305,19 @@ let self = _self // overrides; _self = with self; {
     };
   };
 
+  SysVirt = buildPerlPackage rec {
+    name = "Sys-Virt-1.2.9";
+    src = fetchurl {
+      url = "mirror://cpan/authors/id/D/DA/DANBERR/${name}.tar.gz";
+      sha256 = "1ag55mlkbf63iq3q5mxdawf29c2nyphd52kbshnlim3lax247ml7";
+    };
+    propagatedBuildInputs = [XMLXPath];
+    buildInputs = [TestPodCoverage TimeHiRes TestPod pkgs.pkgconfig pkgs.libvirt];
+    meta = {
+      platforms = stdenv.lib.platforms.linux;
+    };
+  };
+
   TAPParserSourceHandlerpgTAP = buildPerlModule {
     name = "TAP-Parser-SourceHandler-pgTAP-3.30";
     src = fetchurl {