Merge pull request #6697 from ardumont/add-tuxguitar

[new] tuxguitar derivation

3 files changed, 58 insertions, 4 deletions

diff --git a/pkgs/applications/editors/music/tuxguitar/default.nix b/pkgs/applications/editors/music/tuxguitar/default.nix
new file mode 100644
index 000000000000..09d30ad4e17a
--- /dev/null
+++ b/pkgs/applications/editors/music/tuxguitar/default.nix
@@ -0,0 +1,44 @@
+{ stdenv, fetchurl, swt, jdk, makeWrapper, alsaLib }:
+
+let metadata = if stdenv.system == "i686-linux"
+               then { arch = "x86"; sha256 = "1qmb51k0538pn7gv4nsvhfv33xik4l4af0qmpllkzrikmj8wvzlb"; }
+               else if stdenv.system == "x86_64-linux"
+                    then { arch = "x86_64"; sha256 = "12af47jhlrh9aq5b3d13l7cdhlndgnfpy61gz002hajbq7i00ixh"; }
+                    else { };
+in stdenv.mkDerivation rec {
+  version = "1.2";
+  name = "tuxguitar-${version}";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/tuxguitar/${name}-linux-${metadata.arch}.tar.gz";
+    sha256 = metadata.sha256;
+  };
+
+  buildInputs = [ makeWrapper ];
+
+  installPhase = ''
+    mkdir -p $out/bin
+    cp -r lib share $out/
+    cp tuxguitar $out/bin/tuxguitar
+    cp tuxguitar.jar $out/lib
+
+    ln -s $out/share $out/bin/share
+
+    wrapProgram $out/bin/tuxguitar \
+      --set JAVA "${jdk}/bin/java" \
+      --prefix LD_LIBRARY_PATH : "$out/lib/:${swt}/lib:${alsaLib}/lib" \
+      --prefix CLASSPATH : "${swt}/jars/swt.jar:$out/lib/tuxguitar.jar:$out/lib/itext.jar"
+  '';
+
+  meta = with stdenv.lib; {
+    description = "A multitrack guitar tablature editor";
+    longDescription = ''
+      TuxGuitar is a multitrack guitar tablature editor and player written
+      in Java-SWT. It can open GuitarPro, PowerTab and TablEdit files.
+    '';
+    homepage = http://www.tuxguitar.com.ar/;
+    license = licenses.lgpl2;
+    maintainers = [ maintainers.ardumont ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/development/libraries/java/swt/default.nix b/pkgs/development/libraries/java/swt/default.nix
index f64edce7b4c1..795062f12d5f 100644
--- a/pkgs/development/libraries/java/swt/default.nix
+++ b/pkgs/development/libraries/java/swt/default.nix
@@ -6,16 +6,24 @@
 , libsoup
 }:
 
-stdenv.mkDerivation {
-  name = "swt-3.7.2-201202080800";
+let metadata = if stdenv.system == "i686-linux"
+               then { arch = "x86"; sha256 = "10si8kmc7c9qmbpzs76609wkfb784pln3qpmra73gb3fbk7z8caf"; }
+               else if stdenv.system == "x86_64-linux"
+                    then { arch = "x86_64"; sha256 = "0hq48zfqx2p0fqr0rlabnz2pdj0874k19918a4dbj0fhzkhrh959"; }
+                    else { };
+in stdenv.mkDerivation rec {
+  version = "3.7.2";
+  fullVersion = "${version}-201202080800";
+  name = "swt-${version}";
+
   builder = ./builder.sh;
 
   # Alas, the Eclipse Project apparently doesn't produce source-only
   # releases of SWT.  So we just grab a binary release and extract
   # "src.zip" from that.
   src = fetchurl {
-    url = "http://archive.eclipse.org/eclipse/downloads/drops/R-3.7.2-201202080800/swt-3.7.2-gtk-linux-x86.zip";
-    sha256 = "10si8kmc7c9qmbpzs76609wkfb784pln3qpmra73gb3fbk7z8caf";
+    url = "http://archive.eclipse.org/eclipse/downloads/drops/R-${fullVersion}/${name}-gtk-linux-${metadata.arch}.zip";
+    sha256 = metadata.sha256;
   };
 
   buildInputs = [unzip jdk pkgconfig gtk libXtst libXi mesa webkit libsoup];
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index d90b5cbbbf70..29380ca4fbbf 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -11697,6 +11697,8 @@ let
 
   tribler = callPackage ../applications/networking/p2p/tribler { };
 
+  tuxguitar = callPackage ../applications/editors/music/tuxguitar { };
+
   twister = callPackage ../applications/networking/p2p/twister { };
 
   twmn = callPackage ../applications/misc/twmn { };